mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
1f145080dd
https://samba.org seems to be gone, switch to https://www.samba.org Signed-off-by: Konrad Weihmann <kweihmann@outlook.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> (cherry picked from commit 9a85b925c51308f93475d7cc8e2ddda90dff30fd) Signed-off-by: Armin Kuster <akuster808@gmail.com>
55 lines
2.1 KiB
BlitzBasic
55 lines
2.1 KiB
BlitzBasic
SUMMARY = "Hierarchical, reference counted memory pool system with destructors"
|
|
HOMEPAGE = "http://talloc.samba.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL-3.0+ & GPL-3.0+"
|
|
LIC_FILES_CHKSUM = "file://talloc.h;beginline=3;endline=27;md5=a301712782cad6dd6d5228bfa7825249 \
|
|
file://pytalloc.h;beginline=1;endline=18;md5=2c498cc6f2263672483237b20f46b43d"
|
|
|
|
|
|
SRC_URI = "https://www.samba.org/ftp/talloc/talloc-${PV}.tar.gz \
|
|
file://options-2.2.0.patch \
|
|
file://0001-waf-add-support-of-cross_compile.patch \
|
|
"
|
|
SRC_URI[md5sum] = "8416b153547add81cd1a4d24e598c890"
|
|
SRC_URI[sha256sum] = "75d5bcb34482545a82ffb06da8f6c797f963a0da450d0830c669267b14992fc6"
|
|
|
|
inherit waf-samba
|
|
|
|
PACKAGECONFIG ??= "\
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'acl', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'attr', '', d)} \
|
|
"
|
|
PACKAGECONFIG[acl] = "--with-acl,--without-acl,acl"
|
|
PACKAGECONFIG[attr] = "--with-attr,--without-attr,attr"
|
|
PACKAGECONFIG[libaio] = "--with-libaio,--without-libaio,libaio"
|
|
PACKAGECONFIG[libbsd] = "--with-libbsd,--without-libbsd,libbsd"
|
|
PACKAGECONFIG[libcap] = "--with-libcap,--without-libcap,libcap"
|
|
PACKAGECONFIG[valgrind] = "--with-valgrind,--without-valgrind,valgrind"
|
|
|
|
SRC_URI += "${@bb.utils.contains('PACKAGECONFIG', 'attr', '', 'file://avoid-attr-unless-wanted.patch', d)}"
|
|
|
|
S = "${WORKDIR}/talloc-${PV}"
|
|
|
|
#cross_compile cannot use preforked process, since fork process earlier than point subproces.popen
|
|
#to cross Popen
|
|
export WAF_NO_PREFORK="yes"
|
|
|
|
EXTRA_OECONF += "--disable-rpath \
|
|
--disable-rpath-install \
|
|
--bundled-libraries=NONE \
|
|
--builtin-libraries=replace \
|
|
--disable-silent-rules \
|
|
--with-libiconv=${STAGING_DIR_HOST}${prefix}\
|
|
"
|
|
|
|
PACKAGES += "pytalloc pytalloc-dev"
|
|
|
|
RPROVIDES_${PN}-dbg += "pytalloc-dbg"
|
|
|
|
FILES_pytalloc = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/* \
|
|
${libdir}/libpytalloc-util.so.2 \
|
|
${libdir}/libpytalloc-util.so.2.1.1 \
|
|
"
|
|
FILES_pytalloc-dev = "${libdir}/libpytalloc-util.so"
|
|
RDEPENDS_pytalloc = "python3"
|