mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-16 17:13:00 +00:00
deee226017
Add patch for CVE issue: CVE-2018-16301
Link: 8ab211a7ec
Upstream-Status: Pending
Issue: MGUBSYS-5370
Change-Id: I2aac084e61ba9d71ae614a97b4924eaa60328b79
Signed-off-by: Riyaz Ahmed Khan <Riyaz.Khan@kpit.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
59 lines
1.7 KiB
BlitzBasic
59 lines
1.7 KiB
BlitzBasic
SUMMARY = "A sophisticated network protocol analyzer"
|
|
HOMEPAGE = "http://www.tcpdump.org/"
|
|
SECTION = "net"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1d4b0366557951c84a94fabe3529f867"
|
|
|
|
DEPENDS = "libpcap"
|
|
|
|
RDEPENDS_${PN}-ptest += " make perl \
|
|
perl-module-file-basename \
|
|
perl-module-posix \
|
|
perl-module-carp"
|
|
|
|
SRC_URI = " \
|
|
http://www.tcpdump.org/release/${BP}.tar.gz \
|
|
file://unnecessary-to-check-libpcap.patch \
|
|
file://avoid-absolute-path-when-searching-for-libdlpi.patch \
|
|
file://add-ptest.patch \
|
|
file://run-ptest \
|
|
file://0001-PPP-When-un-escaping-don-t-allocate-a-too-large-buff.patch \
|
|
file://CVE-2018-16301.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "a4ead41d371f91aa0a2287f589958bae"
|
|
SRC_URI[sha256sum] = "2cd47cb3d460b6ff75f4a9940f594317ad456cfbf2bd2c8e5151e16559db6410"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
PACKAGECONFIG ?= "openssl"
|
|
|
|
PACKAGECONFIG[libcap-ng] = "--with-cap-ng,--without-cap-ng,libcap-ng"
|
|
PACKAGECONFIG[openssl] = "--with-crypto,--without-crypto,openssl"
|
|
PACKAGECONFIG[smi] = "--with-smi,--without-smi,libsmi"
|
|
# Note: CVE-2018-10103 (SMB - partially fixed, but SMB printing disabled)
|
|
PACKAGECONFIG[smb] = "--enable-smb,--disable-smb"
|
|
|
|
EXTRA_AUTORECONF += "-I m4"
|
|
|
|
do_configure_prepend() {
|
|
mkdir -p ${S}/m4
|
|
if [ -f aclocal.m4 ]; then
|
|
mv aclocal.m4 ${S}/m4
|
|
fi
|
|
}
|
|
|
|
do_install_append() {
|
|
# make install installs an unneeded extra copy of the tcpdump binary
|
|
rm -f ${D}${sbindir}/tcpdump.${PV}
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|
|
|
|
#https://nvd.nist.gov/vuln/detail/CVE-2020-8036
|
|
#Introduce in 4.9 by 246ca110 Autosar SOME/IP protocol support
|
|
#which does not exist in 4.9.3
|
|
CVE_CHECK_WHITELIST += "CVE-2020-8036"
|