mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-10-01 13:23:30 +00:00
a82e2fbdfa
More information on: https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=976228 | A buffer overflow in the dlt_filter_load function in dlt_common.c in | dlt-daemon 2.8.5 (GENIVI Diagnostic Log and Trace) allows arbitrary | code execution because fscanf is misused (no limit on the number of | characters to be read in a format argument). Signed-off-by: Gianfranco Costamagna <costamagnagianfranco@yahoo.it> Signed-off-by: Gianfranco Costamagna <locutusofborg@debian.org> Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
70 lines
3.1 KiB
BlitzBasic
70 lines
3.1 KiB
BlitzBasic
SUMMARY = "Diagnostic Log and Trace"
|
|
DESCRIPTION = "This component provides a standardised log and trace interface, \
|
|
based on the standardised protocol specified in the AUTOSAR standard 4.0 DLT. \
|
|
This component can be used by GENIVI components and other applications as \
|
|
logging facility providing: \
|
|
- the DLT shared library \
|
|
- the DLT daemon, including startup scripts \
|
|
- the DLT daemon adaptors- the DLT client console utilities \
|
|
- the DLT test applications"
|
|
HOMEPAGE = "https://www.genivi.org/"
|
|
SECTION = "console/utils"
|
|
LICENSE = "MPLv2"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=8184208060df880fe3137b93eb88aeea"
|
|
|
|
DEPENDS = "zlib gzip-native"
|
|
|
|
SRC_URI = "git://github.com/GENIVI/${BPN}.git;protocol=https \
|
|
file://0002-Don-t-execute-processes-as-a-specific-user.patch \
|
|
file://0004-Modify-systemd-config-directory.patch \
|
|
file://241.patch \
|
|
file://245.patch \
|
|
file://275.patch \
|
|
"
|
|
SRCREV = "f1ac087c766827b1d0ed9c3a814b3cc052e948f2"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', ' systemd systemd-watchdog systemd-journal dlt-examples dlt-adaptor dlt-console ', '', d)} \
|
|
udp-connection dlt-system dlt-filetransfer "
|
|
# dlt-dbus
|
|
|
|
# General options
|
|
PACKAGECONFIG[dlt-examples] = "-DWITH_DLT_EXAMPLES=ON,-DWITH_DLT_EXAMPLES=OFF,,dlt-daemon-systemd"
|
|
|
|
# Linux options
|
|
PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF,systemd"
|
|
PACKAGECONFIG[systemd-watchdog] = "-DWITH_SYSTEMD_WATCHDOG=ON,-DWITH_SYSTEMD_WATCHDOG=OFF,systemd,libsystemd"
|
|
PACKAGECONFIG[systemd-journal] = "-DWITH_SYSTEMD_JOURNAL=ON,-DWITH_SYSTEMD_JOURNAL=OFF,systemd,libsystemd"
|
|
PACKAGECONFIG[dlt-dbus] = "-DWITH_DLT_DBUS=ON,-DWITH_DLT_DBUS=OFF,dbus,dbus-lib"
|
|
PACKAGECONFIG[udp-connection] = "-DWITH_UDP_CONNECTION=ON,-DWITH_UDP_CONNECTION=OFF"
|
|
|
|
# Command line options
|
|
PACKAGECONFIG[dlt-system] = "-DWITH_DLT_SYSTEM=ON,-DWITH_DLT_SYSTEM=OFF"
|
|
PACKAGECONFIG[dlt-adaptor] = "-DWITH_DLT_ADAPTOR=ON,-DWITH_DLT_ADAPTOR=OFF,,dlt-daemon-systemd"
|
|
PACKAGECONFIG[dlt-filetransfer] = "-DWITH_DLT_FILETRANSFER=ON,-DWITH_DLT_FILETRANSFER=OFF"
|
|
PACKAGECONFIG[dlt-console] = "-DWITH_DLT_CONSOLE=ON,-DWITH_DLT_CONSOLE=OFF,,dlt-daemon-systemd"
|
|
|
|
inherit autotools gettext cmake systemd
|
|
|
|
EXTRA_OECMAKE += "-DSYSTEMD_UNITDIR=${systemd_system_unitdir}"
|
|
|
|
PACKAGES += "${PN}-systemd"
|
|
SYSTEMD_PACKAGES = "${PN} ${PN}-systemd"
|
|
SYSTEMD_SERVICE_${PN} = " ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'dlt.service', '', d)} \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'dlt-system', 'dlt-system.service', '', d)} \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'dlt-dbus', 'dlt-dbus.service', '', d)}"
|
|
SYSTEMD_AUTO_ENABLE_${PN} = "enable"
|
|
SYSTEMD_SERVICE_${PN}-systemd = " \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'dlt-adaptor', 'dlt-adaptor-udp.service', '', d)} \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples', 'dlt-example-user.service', '', d)} \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'dlt-examples dlt-console', 'dlt-receive.service', '', d)} \
|
|
"
|
|
SYSTEMD_AUTO_ENABLE_${PN}-systemd = "disable"
|
|
|
|
FILES_${PN}-doc += "${datadir}/dlt-filetransfer"
|
|
|
|
do_install_append() {
|
|
rm -f ${D}${bindir}/dlt-test-*
|
|
}
|