mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
9650622e07
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
39 lines
1.3 KiB
BlitzBasic
39 lines
1.3 KiB
BlitzBasic
SUMMARY = "Grilo is a framework for searching media content from various sources"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
DEPENDS = " \
|
|
libxml2 \
|
|
glib-2.0 \
|
|
"
|
|
|
|
inherit gnomebase gobject-introspection gtk-doc gettext vala
|
|
|
|
SRC_URI[archive.sha256sum] = "0869c81d19ab139c667d79567c14ddcb6cb5cbfc0108d04cade287eb29536706"
|
|
|
|
GIR_MESON_OPTION = "enable-introspection"
|
|
GTKDOC_MESON_OPTION = "enable-gtk-doc"
|
|
|
|
PACKAGECONFIG ??= "net"
|
|
|
|
PACKAGECONFIG[net] = "-Denable-grl-net=true, -Denable-grl-net=false, libsoup-3.0"
|
|
PACKAGECONFIG[test-ui] = "-Denable-test-ui=true, -Denable-test-ui=false, gtk+3 liboauth"
|
|
|
|
# Once we have a recipe for 'totem-plparser' this can turn into a PACKAGECONFIG
|
|
EXTRA_OEMESON = "-Denable-grl-pls=false"
|
|
|
|
do_compile:append() {
|
|
# grl-type-builtins.* are generated by glib-mkenums which leave full paths
|
|
# in comment and #include directives. Rewrite those before *-src packaging.
|
|
|
|
# Path can be relative to B or WORKDIR in devtool modify
|
|
for base in ${B} ${WORKDIR} ; do
|
|
relpath="$(realpath --relative-to="$base" "${S}")"
|
|
sed -i -e "s,$base/$relpath/src/,," \
|
|
${B}/src/grl-type-builtins.h \
|
|
${B}/src/grl-type-builtins.c
|
|
done
|
|
}
|
|
|
|
FILES:${PN} += "${libdir}/girepository-1.0"
|