mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
60e60fed31
Ptest results: $ run-ptest PASS: async_shutdown PASS: block PASS: bug328 PASS: bug777 PASS: bus PASS: cmsg PASS: device PASS: device4 PASS: device5 PASS: device6 PASS: device7 PASS: domain PASS: emfile PASS: hash PASS: inproc PASS: inproc_shutdown PASS: iovec PASS: ipc PASS: ipc_shutdown PASS: ipc_stress PASS: list PASS: msg PASS: pair PASS: pipeline PASS: poll PASS: prio PASS: pubsub PASS: reqrep PASS: reqttl PASS: separation PASS: shutdown PASS: stats PASS: survey PASS: surveyttl PASS: symbol PASS: tcp PASS: tcp_shutdown PASS: term PASS: timeo PASS: trie PASS: ws PASS: ws_async_shutdown PASS: zerocopy Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
42 lines
1.4 KiB
BlitzBasic
42 lines
1.4 KiB
BlitzBasic
SUMMARY = "nanomsg socket library"
|
|
DESCRIPTION = "nanomsg is a socket library that provides several common \
|
|
communication patterns. It aims to make the networking layer fast, scalable, \
|
|
and easy to use. Implemented in C, it works on a wide range of operating \
|
|
systems with no further dependencies."
|
|
HOMEPAGE = "https://nanomsg.org/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=587b3fd7fd291e418ff4d2b8f3904755"
|
|
|
|
SECTION = "libs/networking"
|
|
|
|
SRC_URI = "git://github.com/nanomsg/nanomsg.git;protocol=https;branch=master \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRCREV = "ccd7f20c1b756f7041598383baffcdc326246db7"
|
|
|
|
inherit cmake pkgconfig ptest
|
|
|
|
# nanomsg documentation generation requires asciidoctor,
|
|
# not asciidoc, and currently there's no asciidoctor-native
|
|
# recipe anywhere in openembedded-core or meta-openembedded
|
|
EXTRA_OECMAKE = " -DNN_ENABLE_DOC=OFF \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', '-DNN_TESTS=ON', '', d)} \
|
|
"
|
|
|
|
# we don't want nanomsg-tools to be renamed to libnanomsg-tools
|
|
DEBIAN_NOAUTONAME:${PN}-tools = "1"
|
|
|
|
do_install_ptest(){
|
|
install -d ${D}/${PTEST_PATH}/tests
|
|
find ${B} -maxdepth 1 -type f -executable \
|
|
! -name "*_lat" \
|
|
! -name "*_thr" \
|
|
! -name "nanocat" \
|
|
! -name "libnanomsg.so*" \
|
|
-exec install {} ${D}${PTEST_PATH}/tests/ \;
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tools"
|
|
FILES:${PN}-tools = "${bindir}/*"
|