mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-08-14 18:59:27 +00:00
6ac3bc3950
0001-vrrp-Don-t-include-linux-if_ether.h-if-not-needed.patch is included in this release, so drop the patch. Many changes and updates, easier to look in the changelogs themselves rather than pasting here: https://www.keepalived.org/release-notes/Release-2.3.3.html https://www.keepalived.org/release-notes/Release-2.3.4.html Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
61 lines
2.4 KiB
BlitzBasic
61 lines
2.4 KiB
BlitzBasic
SUMMARY = "High Availability monitor built upon LVS, VRRP and service pollers"
|
|
DESCRIPTION = "Keepalived is a routing software written in C. The main goal \
|
|
of this project is to provide simple and robust facilities for loadbalancing \
|
|
and high-availability to Linux system and Linux based infrastructures. \
|
|
Loadbalancing framework relies on well-known and widely used Linux Virtual \
|
|
Server (IPVS) kernel module providing Layer4 loadbalancing \
|
|
"
|
|
HOMEPAGE = "http://www.keepalived.org/"
|
|
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "http://www.keepalived.org/software/${BP}.tar.gz \
|
|
file://0001-configure.ac-Do-not-emit-compiler-flags-into-object-.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "6afd95ddb7d3e0d3b8b8e5b3a489144131b61a01b06d29e883d0c44acc8a36bf"
|
|
UPSTREAM_CHECK_URI = "https://github.com/acassen/keepalived/releases"
|
|
|
|
DEPENDS = "libnfnetlink openssl"
|
|
|
|
inherit autotools pkgconfig systemd
|
|
|
|
PACKAGECONFIG ??= "libnl snmp reproducible \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
"
|
|
PACKAGECONFIG[libnl] = "--enable-libnl,--disable-libnl,libnl"
|
|
PACKAGECONFIG[reproducible] = "--enable-reproducible-build,,"
|
|
PACKAGECONFIG[snmp] = "--enable-snmp,--disable-snmp,net-snmp"
|
|
PACKAGECONFIG[systemd] = "--with-init=systemd --with-systemdsystemunitdir=${systemd_system_unitdir},--with-init=SYSV,systemd"
|
|
|
|
EXTRA_OEMAKE = "initdir=${sysconfdir}/init.d"
|
|
|
|
export EXTRA_CFLAGS = "${CFLAGS}"
|
|
|
|
do_configure:append() {
|
|
sed -i -e 's|${WORKDIR}|<scrubbed>|g' ${B}/lib/config.h
|
|
}
|
|
|
|
do_install:append() {
|
|
if [ -f ${D}${sysconfdir}/init.d/${BPN} ]; then
|
|
chmod 0755 ${D}${sysconfdir}/init.d/${BPN}
|
|
sed -i 's#rc.d/##' ${D}${sysconfdir}/init.d/${BPN}
|
|
fi
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -D -m 0644 ${B}/${BPN}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
|
|
fi
|
|
if [ -n "${@bb.utils.filter('PACKAGECONFIG', 'reproducible', d)}" ]; then
|
|
sed -i -e 's|${WORKDIR}|<scrubbed>|g' ${D}${sysconfdir}/keepalived/keepalived.config-opts
|
|
fi
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "${PN}-samples"
|
|
|
|
FILES:${PN} += "${datadir}/snmp/mibs/KEEPALIVED-MIB.txt"
|
|
|
|
FILES:${PN}-samples = "${sysconfdir}/keepalived/samples ${sysconfdir}/keepalived/keepalived.conf.sample"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "keepalived.service"
|
|
SYSTEMD_AUTO_ENABLE ?= "disable"
|