mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
92c8880aa3
Changelogs: https://github.com/linux-nvme/nvme-cli/releases/tag/v2.16 https://github.com/linux-nvme/nvme-cli/releases/tag/v2.15 https://github.com/linux-nvme/nvme-cli/releases/tag/v2.14 https://github.com/linux-nvme/nvme-cli/releases/tag/v2.13 Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
35 lines
1.4 KiB
BlitzBasic
35 lines
1.4 KiB
BlitzBasic
SUMMARY = "NVMe management command line interface"
|
|
HOMEPAGE = "https://github.com/linux-nvme/nvme-cli"
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPL-2.0-only & CC0-1.0 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=8264535c0c4e9c6c335635c4026a8022 \
|
|
file://ccan/licenses/CC0;md5=c17af43b05840255a6fedc5eda9d56cc \
|
|
file://ccan/licenses/BSD-MIT;md5=838c366f69b72c5df05c96dff79b35f2"
|
|
DEPENDS = "json-c libnvme"
|
|
SRCREV = "faf7326a2997dea91687fd3daa17fc405910a4c1"
|
|
|
|
SRC_URI = "git://github.com/linux-nvme/nvme-cli.git;branch=master;protocol=https;tag=v${PV}"
|
|
|
|
inherit bash-completion meson pkgconfig systemd
|
|
|
|
EXTRA_OEMESON += "-Dsystemddir=${systemd_unitdir}/system"
|
|
|
|
pkg_postinst_ontarget:${PN}-user () {
|
|
${sbindir}/nvme gen-hostnqn > ${sysconfdir}/nvme/hostnqn
|
|
${bindir}/uuidgen > ${sysconfdir}/nvme/hostid
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-dracut ${PN}-zsh-completion ${PN}-user"
|
|
|
|
FILES:${PN} += "${systemd_system_unitdir}"
|
|
FILES:${PN}-dracut = "${nonarch_libdir}/dracut/dracut.conf.d"
|
|
FILES:${PN}-zsh-completion = "${datadir}/zsh/site-functions"
|
|
ALLOW_EMPTY:${PN}-user = "1"
|
|
|
|
RDEPENDS:${PN}-user = "util-linux-uuidgen"
|
|
|
|
# This one is reproducible only on 32bit MACHINEs
|
|
# http://errors.yoctoproject.org/Errors/Details/766964/
|
|
# git/plugins/virtium/virtium-nvme.c:205:63: error: passing argument 1 of 'localtime' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|