mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
38 lines
1.0 KiB
BlitzBasic
38 lines
1.0 KiB
BlitzBasic
SUMMARY = "A user tool to support sleeping some number of microseconds"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
|
|
S = "${UNPACKDIR}"
|
|
DEPENDS = "popt"
|
|
|
|
SRC_URI = "file://usleep.c \
|
|
file://usleep.1 \
|
|
file://GPLv2.patch \
|
|
"
|
|
|
|
do_compile() {
|
|
${CC} ${CFLAGS} ${LDFLAGS} usleep.c -o usleep -lpopt
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${base_bindir}
|
|
install -d ${D}${mandir}/man1
|
|
|
|
install -m 0755 ${UNPACKDIR}/usleep ${D}${base_bindir}
|
|
install -m 0644 ${UNPACKDIR}/usleep.1 ${D}${mandir}/man1
|
|
}
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE:${PN} = "usleep"
|
|
ALTERNATIVE_PRIORITY = "80"
|
|
ALTERNATIVE_LINK_NAME[usleep] = "${base_bindir}/usleep"
|
|
|
|
ALTERNATIVE:${PN}-doc = "usleep.1"
|
|
ALTERNATIVE_LINK_NAME[usleep.1] = "${mandir}/man1/usleep.1"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/766900/
|
|
# usleep.c:47:43: error: passing argument 3 of 'poptGetContext' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|