mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
ba323d198f
Add openssl as a dependency. Fixes compilation error: | sign.c:16:10: fatal error: openssl/opensslv.h: No such file or directory | 16 | #include <openssl/opensslv.h> Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
50 lines
1.2 KiB
BlitzBasic
50 lines
1.2 KiB
BlitzBasic
SUMMARY = "Inspect and manipulate eBPF programs and maps"
|
|
DESCRIPTION = "bpftool is a kernel tool for inspection and simple manipulation \
|
|
of eBPF programs and maps."
|
|
LICENSE = "GPL-2.0-only"
|
|
DEPENDS = "binutils elfutils elfutils-native openssl"
|
|
PROVIDES = "virtual/bpftool"
|
|
|
|
inherit bash-completion kernelsrc kernel-arch
|
|
|
|
do_populate_lic[depends] += "virtual/kernel:do_shared_workdir"
|
|
|
|
EXTRA_OEMAKE = "\
|
|
V=1 \
|
|
-C ${S}/tools/bpf/bpftool \
|
|
O=${B} \
|
|
CROSS=${TARGET_PREFIX} \
|
|
CC="${CC} ${DEBUG_PREFIX_MAP} -ffile-prefix-map=${STAGING_KERNEL_DIR}=${KERNEL_SRC_PATH} ${CFLAGS}" \
|
|
HOSTCC="${BUILD_CC} ${BUILD_CFLAGS}" \
|
|
LD="${LD}" \
|
|
AR=${AR} \
|
|
ARCH=${ARCH} \
|
|
bash_compdir=${prefix}/share/bash-completion \
|
|
"
|
|
|
|
SECURITY_CFLAGS = ""
|
|
|
|
do_configure[depends] += "virtual/kernel:do_shared_workdir"
|
|
|
|
COMPATIBLE_HOST = "(x86_64|aarch64|riscv64).*-linux"
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
python do_package:prepend() {
|
|
d.setVar('PKGV', d.getVar("KERNEL_VERSION").split("-")[0])
|
|
}
|
|
|
|
B = "${WORKDIR}/${BPN}-${PV}"
|
|
|
|
FILES:${PN} += "${exec_prefix}/sbin/*"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|