mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-29 04:30:41 +00:00
8a62579490
* Upstream changed from pcre to pcre2 * with-tcsetpgrp was dropped in "53081: remove old BeOS support code" Changes * POSIX real-time signals (SIGRTMIN etc) are now supported by the kill and trap builtins, TRAP* functions, and the signals parameter, where available. * The kill builtin learnt a new option -q to send the signal via sigqueue(3) along with an arbitrary integer value, where available. * The kill builtin also learnt a new -L option to print a list of all known signal numbers and their names. * The new completion helper _as_if can be used to complete one command as if it were another command with particular arguments. Signed-off-by: Jörg Sommer <joerg.sommer@navimatix.de> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
60 lines
2.0 KiB
BlitzBasic
60 lines
2.0 KiB
BlitzBasic
SUMMARY = "UNIX Shell similar to the Korn shell"
|
|
DESCRIPTION = "Zsh is a shell designed for interactive use, although it is also a \
|
|
powerful scripting language. Many of the useful features of bash, \
|
|
ksh, and tcsh were incorporated into zsh; many original features were added."
|
|
HOMEPAGE = "http://www.zsh.org"
|
|
SECTION = "base/shell"
|
|
|
|
LICENSE = "zsh"
|
|
LIC_FILES_CHKSUM = "file://LICENCE;md5=1a4c4cda3e8096d2fd483ff2f4514fec"
|
|
|
|
DEPENDS = "ncurses bison-native libcap libpcre2 gdbm groff-native"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/project/${BPN}/${BPN}/${PV}/${BP}.tar.xz"
|
|
SRC_URI[sha256sum] = "5d20bec03f981dc4e9a09ec245e7415388ff641f79c5c5c416b5042e58d8280d"
|
|
|
|
inherit autotools gettext update-alternatives manpages
|
|
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
EXTRA_OECONF = " \
|
|
--bindir=${base_bindir} \
|
|
--enable-etcdir=${sysconfdir} \
|
|
--enable-fndir=${datadir}/${BPN}/${PV}/functions \
|
|
--enable-site-fndir=${datadir}/${BPN}/site-functions \
|
|
--with-term-lib='ncursesw ncurses' \
|
|
--enable-cap \
|
|
--enable-multibyte \
|
|
--disable-gdbm \
|
|
--disable-dynamic \
|
|
zsh_cv_shared_environ=yes \
|
|
"
|
|
|
|
# Configure respects --bindir from EXTRA_OECONF, but then Src/Makefile will read bindir from environment
|
|
export bindir = "${base_bindir}"
|
|
|
|
EXTRA_OEMAKE = "-e MAKEFLAGS="
|
|
|
|
ALTERNATIVE:${PN} = "sh"
|
|
ALTERNATIVE_LINK_NAME[sh] = "${base_bindir}/sh"
|
|
ALTERNATIVE_TARGET[sh] = "${base_bindir}/${BPN}"
|
|
ALTERNATIVE_PRIORITY = "90"
|
|
|
|
# Needed for manpages.bbclass, but they're always installed
|
|
PACKAGECONFIG[manpages] = ""
|
|
|
|
do_install:append() {
|
|
sed -i -e '1!b; s:^#!.*[ /]zsh:#!${bindir}/zsh:; s#/usr/local/bin#${bindir}#;' \
|
|
`find ${D}/usr/share/zsh/${PV}/functions -type f`
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
touch $D${sysconfdir}/shells
|
|
for i in zsh sh
|
|
do
|
|
grep -q "bin/$i" $D${sysconfdir}/shells || \
|
|
printf >> $D${sysconfdir}/shells \
|
|
"${bindir}/$i\n${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '/bin/$i\n', '', d)}"
|
|
done
|
|
}
|