mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
7d22831770
Added tag to SRC_URI. Release notes [1]: Add lvmlockd compare and write, index man pages, and a lot of fixes. * Add atomic leases using Compare and Write (CAW) to lvmlockd. * Add lvm-index(7), lvm-categories(7) and lvm-args(7) man pages. * Use temporary activations for integrity, writecache, thin and VDO pool conv preventing interference. * Fix `vgreduce --removemissing --force` infinite loop for raid/mirror snapshot. * Improve RAID LV health report to distinguish 'refresh needed' from 'repair needed'. * Support `--interval +N` to delay first poll in pvmove and lvpoll. * Show active cache mode in kernel table line with `lvs -o kernel_cache_mode`. * Reject lvreduce of CoW snapshot COW store when it would truncate exception data. * Skip filesystem resize handling for CoW snapshot COW store LVs in lvresize. * Fix vgsplit to not fail on no active LV on a PV being split to an existing VG. * Preserve file desciptors with CLOEXEC opened in library constructors. * Add lvmpolld 'cmd' log keyword to enable verbose lvpoll output. * Add `activate_lv_temporary()` to consolidate `LV_TEMPORARY` and sync handling. * Add missing sync in `add_mirror_log()` and `activate_and_wipe_lv_list()`. * Fix cachevol cmeta/cdata device offsets. * Fix pofile generation to include SOURCES2 binaries and update xgettext options. [1] https://github.com/lvmteam/lvm2/releases/tag/v2_03_39 Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
84 lines
3.0 KiB
PHP
84 lines
3.0 KiB
PHP
HOMEPAGE = "https://www.sourceware.org/lvm2/"
|
|
SECTION = "utils"
|
|
DESCRIPTION = "LVM2 is a set of utilities to manage logical volumes in Linux."
|
|
LICENSE = "GPL-2.0-only & LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=12713b4d9386533feeb07d6e4831765a \
|
|
file://COPYING.LIB;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
DEPENDS += "libaio"
|
|
|
|
SRC_URI = "git://sourceware.org/git/lvm2.git;branch=main;tag=${PV_TAG} \
|
|
file://lvm.conf \
|
|
file://0001-implement-libc-specific-reopen_stream.patch \
|
|
file://0004-tweak-MODPROBE_CMD-for-cross-compile.patch \
|
|
file://0001-Avoid-bashisms-in-init-scripts.patch \
|
|
file://0005-do-not-build-manual.patch \
|
|
file://0006-start-lvm2-monitor.service-after-tmp.mount.patch \
|
|
file://reproducible-build.patch \
|
|
file://0001-include-libgen.h-for-basename.patch \
|
|
"
|
|
|
|
SRCREV = "6c5b6cee9f21908bdaff830c210222cc7e08f1ab"
|
|
PV = "2.03.39"
|
|
PV_TAG = "v${@d.getVar('PV').replace('.', '_')}"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\_\d+)+)"
|
|
|
|
inherit autotools-brokensep pkgconfig systemd
|
|
|
|
def get_dm_version(p):
|
|
import re
|
|
|
|
fn = p + '/VERSION_DM'
|
|
try:
|
|
f = open(fn, 'r')
|
|
except IOError:
|
|
return None
|
|
|
|
lines = f.readlines()
|
|
f.close()
|
|
for line in lines:
|
|
m = re.match(r'(\w+)[-. ](\w+)[-. ](\w+)', line.strip())
|
|
if m:
|
|
return ".".join([m.group(1), m.group(2), m.group(3)])
|
|
|
|
return None
|
|
|
|
DM_VERSION = '${@get_dm_version("${S}")}'
|
|
python do_package:prepend() {
|
|
d.setVar('PKGV:libdevmapper', d.getVar("DM_VERSION"))
|
|
}
|
|
|
|
LVM2_PACKAGECONFIG = "dmeventd"
|
|
LVM2_PACKAGECONFIG:append:class-target = " \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \
|
|
"
|
|
|
|
# odirect is always enabled because there currently is a bug in
|
|
# lib/device/dev-io.c which prevents compiling without it. It is
|
|
# better to stick to configurations that were actually tested by
|
|
# upstream...
|
|
PACKAGECONFIG ??= "odirect ${LVM2_PACKAGECONFIG}"
|
|
|
|
PACKAGECONFIG[dmeventd] = "--enable-dmeventd,--disable-dmeventd"
|
|
PACKAGECONFIG[odirect] = "--enable-o_direct,--disable-o_direct"
|
|
PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline"
|
|
PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux"
|
|
# NOTE: Add thin-provisioning-tools only if your distro policy allows GPL-3.0 license
|
|
PACKAGECONFIG[thin-provisioning-tools] = "--with-thin=internal,--with-thin=none,,thin-provisioning-tools"
|
|
|
|
# Unset user/group to unbreak install.
|
|
EXTRA_OECONF = "--with-user= \
|
|
--with-group= \
|
|
--enable-realtime \
|
|
--enable-cmdlib \
|
|
--enable-pkgconfig \
|
|
--with-usrlibdir=${libdir} \
|
|
--with-systemdsystemunitdir=${systemd_system_unitdir} \
|
|
--disable-thin_check_needs_check \
|
|
--with-thin-check=${sbindir}/thin_check \
|
|
--with-thin-dump=${sbindir}/thin_dump \
|
|
--with-thin-repair=${sbindir}/thin_repair \
|
|
--with-thin-restore=${sbindir}/thin_restore \
|
|
"
|