mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-16 19:37:11 +00:00
210800f123
ERROR: gexiv2-0.14.2-r0 do_package: QA Issue: gexiv2: Files/directories were installed but not shipped in any package: /usr/lib /usr/lib/python3.11 /usr/lib/python3.11/site-packages /usr/lib/python3.11/site-packages/gi /usr/lib/python3.11/site-packages/gi/overrides /usr/lib/python3.11/site-packages/gi/overrides/GExiv2.py /usr/lib/python3.11/site-packages/gi/overrides/__pycache__ /usr/lib/python3.11/site-packages/gi/overrides/__pycache__/GExiv2.cpython-311.pyc Signed-off-by: Lei Maohui <leimaohui@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> (cherry picked from commit eddc2571a759f208cd8e3e05f3ca14457b9169dc) Signed-off-by: Armin Kuster <akuster808@gmail.com>
36 lines
1.1 KiB
BlitzBasic
36 lines
1.1 KiB
BlitzBasic
SUMMARY = "A GObject-based Exiv2 wrapper"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=625f055f41728f84a8d7938acc35bdc2"
|
|
|
|
DEPENDS = "exiv2 python3-pygobject-native"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
|
|
inherit gnomebase gobject-introspection gtk-doc python3native vala
|
|
|
|
SRC_URI[archive.sha256sum] = "2a0c9cf48fbe8b3435008866ffd40b8eddb0667d2212b42396fdf688e93ce0be"
|
|
|
|
EXTRA_OEMESON = " \
|
|
${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Dvapi=true', '-Dvapi=false', d)} \
|
|
"
|
|
|
|
PACKAGES =+ "${PN}-python3"
|
|
FILES:${PN}-python3 = "${PYTHON_SITEPACKAGES_DIR}"
|
|
RDEPENDS:${PN}-python3 = "${PN}"
|
|
|
|
PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess"
|
|
src_package_preprocess () {
|
|
# Trim build paths from comments in generated sources to ensure reproducibility
|
|
sed -i -e "s,${B}/../${BPN}-${PV}/${BPN}/,,g" \
|
|
${B}/gexiv2/gexiv2-enums.cpp
|
|
}
|
|
|
|
do_install:append() {
|
|
# gexiv2 harcodes usr/lib as install path, so this corrects it to actual libdir
|
|
if [ "${prefix}/lib" != "${libdir}" ]; then
|
|
mv ${D}/${prefix}/lib/* ${D}/${libdir}/
|
|
rm -rf ${D}/${prefix}/lib
|
|
fi
|
|
}
|