mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-14 04:28:02 +00:00
a5cb4cc7d4
The command "bitbake universe -c fetch" currently throws a ton of warnings as there are many 'impossible' dependencies. In some cases these variants may never have worked and were just added by copy and paste of recipes. In some cases they once clearly did work but became broken somewhere along the way. Users may also be carrying local bbappend files which add further BBCLASSEXTEND. Having universe fetch work without warnings is desireable so clean up the broken variants. Anyone actually needing something dropped here can propose adding it and the correct functional dependencies back quite easily. This also then ensures we're not carrying or fixing things nobody uses. Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Khem Raj <raj.khem@gmail.com> (cherry picked from commit 9962d57f7c235873de0a0bb192b5f56747762fc7) Signed-off-by: Armin Kuster <akuster808@gmail.com>
53 lines
1.7 KiB
BlitzBasic
53 lines
1.7 KiB
BlitzBasic
DESCRIPTION = "jackdmp is a C++ version of the JACK low-latency audio \
|
|
server for multi-processor machines. It is a new implementation of the \
|
|
JACK server core features that aims in removing some limitations of \
|
|
the JACK1 design. The activation system has been changed for a data \
|
|
flow model and lock-free programming techniques for graph access have \
|
|
been used to have a more dynamic and robust system."
|
|
SECTION = "libs/multimedia"
|
|
|
|
LICENSE = "GPL-2.0-only & LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://common/jack/control.h;beginline=2;endline=21;md5=e6df0bf30cde8b3b825451459488195d \
|
|
file://common/jack/jack.h;beginline=1;endline=19;md5=6b736ed6b810592b135480a5e853392e \
|
|
"
|
|
|
|
DEPENDS = "libsamplerate0 libsndfile1"
|
|
|
|
SRC_URI = "git://github.com/jackaudio/jack2.git;branch=master;protocol=https"
|
|
SRCREV = "4f58969432339a250ce87fe855fb962c67d00ddb"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit waf pkgconfig
|
|
|
|
PACKAGECONFIG ??= "alsa"
|
|
PACKAGECONFIG[alsa] = "--alsa=yes,--alsa=no,alsa-lib"
|
|
# --dbus only stops building jackd -> add --classic
|
|
PACKAGECONFIG[dbus] = "--dbus --classic,,dbus"
|
|
PACKAGECONFIG[opus] = "--opus=yes,--opus=no,libopus"
|
|
|
|
# portaudio is for windows builds only
|
|
EXTRA_OECONF = "--portaudio=no"
|
|
|
|
do_install:append() {
|
|
if ! ${@bb.utils.contains('PACKAGECONFIG', 'dbus', True, False, d)}; then
|
|
rm -f ${D}${bindir}/jack_control
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "libjack jack-server jack-utils"
|
|
|
|
RDEPENDS:jack-dev:remove = "${PN} (= ${EXTENDPKGV})"
|
|
|
|
FILES:libjack = "${libdir}/*.so.* ${libdir}/jack/*.so"
|
|
FILES:jack-server = " \
|
|
${datadir}/dbus-1/services \
|
|
${bindir}/jackdbus \
|
|
${bindir}/jackd \
|
|
"
|
|
FILES:jack-utils = "${bindir}/*"
|
|
|
|
FILES:${PN}-doc += " ${datadir}/jack-audio-connection-kit/reference/html/*"
|
|
|