mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-16 22:23:14 +00:00
33cdf41004
46.1 ==== * Implement linux-drm-syncobj-v1 [Austin; !3300] * Fix input lag on X11 nvidia [Daniel; !3685] * Fix scanout on secondary GPUs [Michel; !3674] * Don't apply max-render-time to secondary GPUs [Michel; !3689] * Fix reusing single-pixel buffers [Jonas Å.; !3702] * Improve scanout candidate check [Robert; !3699] * Always use logical pixels for bounds [Sophie; !3698] * Fix modifiers getting stuck during grabs [Carlos; !3704] * Fix night-light on displays without EDID [Sebastian W.; !3673] * Fix secondary GPU acceleration with nvidia driver [Jonas Å., Daniel; !3304] * Fix some XWayland clients being partially click-through [Sebastian K.; !3697] * Fix initial suspended state [Jonas Å.; !3475] * Fixed crashes [Bilal, Jonas Å., Sebastian W., Daniel; !3683, !3666, !3691, !3708, !3678] * Misc. bug fixes and cleanups [Ray, Carlos, Bilal, Ivan, Barnabás, Jonas Å., Jonas D., Michel; !3672, !3681, !3686, !3687, !3671, !3679, !3690, !3703, !3695, !2946, !3696, !3710, !3644, !3707] Contributors: Jonas Ådahl, Michel Dänzer, Jonas Dreßler, Bilal Elmoussaoui, Carlos Garnacho, Sophie Herold, Sebastian Keller, Robert Mader, Athmane MOKRAOUI, Ivan Molodetskikh, Barnabás Pőcze, Austin Shafer, Ray Strode, Daniel van Vugt, Sebastian Wick Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
110 lines
3.7 KiB
BlitzBasic
110 lines
3.7 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
wayland-native \
|
|
virtual/libx11 \
|
|
colord \
|
|
graphene \
|
|
gtk4 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
libei \
|
|
libxtst \
|
|
libxkbfile \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xinerama', '', d)} \
|
|
xwayland \
|
|
"
|
|
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext features_check
|
|
|
|
SRC_URI[archive.sha256sum] = "63b2660dd0fa193fa662c80ee12eb8b16f2b8c3bc3896366200c79943824d51d"
|
|
|
|
# x11 is still manadatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "wayland x11 polkit"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
REQUIRED_DISTRO_FEATURES += "systemd"
|
|
|
|
# profiler requires sysprof 3.34 which is not willing to build atow
|
|
PACKAGECONFIG ??= " \
|
|
native-backend \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
|
|
sm \
|
|
startup-notification \
|
|
gnome-desktop \
|
|
"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dtests=false \
|
|
-Dnative_tests=false \
|
|
-Dxwayland_path=${bindir}/Xwayland \
|
|
"
|
|
|
|
# combi-config - see meson_options.txt for more details
|
|
PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
|
|
PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
|
|
PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
|
|
PACKAGECONFIG[libdisplay-info] = "-Dlibdisplay_info=true, -Dlibdisplay_info=false, libdisplay-info"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
|
|
# Remove depending on pipewire-0.2 when mutter is upgraded to 3.36+
|
|
PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
|
|
PACKAGECONFIG[gnome-desktop] = "-Dlibgnome_desktop=true, -Dlibgnome_desktop=false, gnome-desktop gnome-settings-daemon"
|
|
PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
|
|
PACKAGECONFIG[sound-player] = "-Dsound_player=true, -Dsound_player=false, libcanberra"
|
|
PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
|
|
PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
|
|
|
|
MUTTER_API_NAME = "mutter-14"
|
|
|
|
do_install:prepend() {
|
|
sed -i -e 's|${B}/||g' ${B}/cogl/cogl/cogl-enum-types.c
|
|
sed -i -e 's|${B}/||g' ${B}/clutter/clutter/clutter-enum-types.c
|
|
sed -i -e 's|${B}/||g' ${B}/src/meta-private-enum-types.c
|
|
sed -i -e 's|${B}/||g' ${B}/src/meta/meta-enum-types.c
|
|
}
|
|
|
|
do_install:append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
GSETTINGS_PACKAGE = "${PN}-gsettings"
|
|
|
|
PACKAGES =+ "${PN}-tests ${PN}-gsettings"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${datadir}/gir-1.0 \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES:${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES:${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "${PN}-gsettings gsettings-desktop-schemas"
|
|
|