mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-16 05:55:45 +00:00
0f98d98e82
CVE-2023-52160: The implementation of PEAP in wpa_supplicant through 2.10 allows authentication bypass. For a successful attack, wpa_supplicant must be configured to not verify the network's TLS certificate during Phase 1 authentication, and an eap_peap_decrypt vulnerability can then be abused to skip Phase 2 authentication. The attack vector is sending an EAP-TLV Success packet instead of starting Phase 2. This allows an adversary to impersonate Enterprise Wi-Fi networks. Reference: https://nvd.nist.gov/vuln/detail/CVE-2023-52160 Patch from: https://w1.fi/cgit/hostap/commit/?id=8e6485a1bcb0baffdea9e55255a81270b768439c Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
60 lines
2.0 KiB
BlitzBasic
60 lines
2.0 KiB
BlitzBasic
SUMMARY = "User space daemon for extended IEEE 802.11 management"
|
|
HOMEPAGE = "http://w1.fi/hostapd/"
|
|
SECTION = "kernel/userland"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://hostapd/README;beginline=5;endline=47;md5=aa03b8bd6216d1a7ca01fd4b89863073"
|
|
|
|
DEPENDS = "libnl openssl"
|
|
|
|
SRC_URI = " \
|
|
http://w1.fi/releases/hostapd-${PV}.tar.gz \
|
|
file://defconfig \
|
|
file://init \
|
|
file://hostapd.service \
|
|
file://CVE-2024-3596_00.patch \
|
|
file://CVE-2024-3596_01.patch \
|
|
file://CVE-2024-3596_02.patch \
|
|
file://CVE-2024-3596_04.patch \
|
|
file://CVE-2024-3596_05.patch \
|
|
file://CVE-2024-3596_06.patch \
|
|
file://CVE-2024-3596_07.patch \
|
|
file://CVE-2024-3596_08.patch \
|
|
file://0001-SAE-Check-for-invalid-Rejected-Groups-element-length.patch \
|
|
file://0003-SAE-Reject-invalid-Rejected-Groups-element-in-the-pa.patch \
|
|
file://CVE-2023-52160.patch \
|
|
"
|
|
|
|
|
|
SRC_URI[sha256sum] = "206e7c799b678572c2e3d12030238784bc4a9f82323b0156b4c9466f1498915d"
|
|
|
|
inherit update-rc.d systemd pkgconfig features_check
|
|
|
|
CONFLICT_DISTRO_FEATURES = "openssl-no-weak-ciphers"
|
|
|
|
INITSCRIPT_NAME = "hostapd"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "hostapd.service"
|
|
SYSTEMD_AUTO_ENABLE:${PN} = "disable"
|
|
|
|
do_configure:append() {
|
|
install -m 0644 ${WORKDIR}/defconfig ${B}/hostapd/.config
|
|
}
|
|
|
|
do_compile() {
|
|
export CFLAGS="-MMD -O2 -Wall -g"
|
|
export EXTRA_CFLAGS="${CFLAGS}"
|
|
make -C hostapd V=1
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${B}/hostapd/hostapd.conf ${D}${sysconfdir}
|
|
install -m 0755 ${B}/hostapd/hostapd ${D}${sbindir}
|
|
install -m 0755 ${B}/hostapd/hostapd_cli ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
|
|
install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service
|
|
}
|
|
|
|
CONFFILES:${PN} += "${sysconfdir}/hostapd.conf"
|