mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-29 22:47:29 +00:00
78751d3726
Remove 0001-Set-use_tcl-to-be-empty-string-if-tcl-is-disabled.patch. This patch is obsolete and not needed because the current graphviz configure.ac has correct logic of checking use_tcl. This use_tcl variable needs to be set when '--disable-tcl' is set, otherwise, things will behave as if no option is supplied and the configure process will check tcl automatically. This patch is problematic because its logic against the current version is wrong. The recipe has already explicitly set '--disable-tcl', so the configure process should not do automatic checking for tcl at do_configure. This patch fixes do_configure error when host has tcl8.6-dev installed. The error is like below: QA Issue: This autoconf log indicates errors, it looked at host include and/or library paths while determining system capabilities. Rerun configure task after fixing this. [configure-unsafe] Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
121 lines
3.7 KiB
BlitzBasic
121 lines
3.7 KiB
BlitzBasic
SUMMARY = "Graph Visualization Tools"
|
|
HOMEPAGE = "http://www.graphviz.org"
|
|
LICENSE = "EPL-1.0"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=9109f5fc16cf963fb3cdd32781b3ce04"
|
|
|
|
DEPENDS = " \
|
|
bison-native \
|
|
groff-native \
|
|
libtool \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
expat \
|
|
freetype \
|
|
"
|
|
DEPENDS:append:class-target = " ${BPN}-native"
|
|
DEPENDS:append:class-nativesdk = " ${BPN}-native"
|
|
|
|
inherit autotools-brokensep pkgconfig gettext qemu
|
|
|
|
SRC_URI = "https://gitlab.com/api/v4/projects/4207231/packages/generic/${BPN}-releases/${PV}/${BP}.tar.xz \
|
|
file://0001-Autotools-fix-do-not-put-prefix-based-paths-in-compi.patch \
|
|
file://CVE-2023-46045-0001.patch \
|
|
file://CVE-2023-46045-0002.patch \
|
|
file://CVE-2023-46045-0003.patch \
|
|
"
|
|
SRC_URI:append:class-nativesdk = "\
|
|
file://graphviz-setup.sh \
|
|
"
|
|
SRC_URI[sha256sum] = "d593695fdaa8a19297523b679ad13d3ef2027b0b7f14cc2bc23e77969ed81565"
|
|
|
|
PACKAGECONFIG ??= "librsvg"
|
|
PACKAGECONFIG[librsvg] = "--with-librsvg,--without-librsvg,librsvg"
|
|
|
|
EXTRA_OECONF:append = " PS2PDF=/bin/echo --disable-man-pdfs"
|
|
|
|
EXTRA_OECONF:class-target = "\
|
|
--with-expatincludedir=${STAGING_INCDIR} \
|
|
--with-expatlibdir=${STAGING_LIBDIR} \
|
|
--without-included-ltdl \
|
|
--disable-java \
|
|
--disable-tcl \
|
|
--disable-r \
|
|
--disable-sharp \
|
|
"
|
|
EXTRA_OECONF:class-nativesdk = "\
|
|
--with-expatincludedir=${STAGING_INCDIR} \
|
|
--with-expatlibdir=${STAGING_LIBDIR} \
|
|
--without-included-ltdl \
|
|
--disable-java \
|
|
--disable-tcl \
|
|
--disable-r \
|
|
--disable-sharp \
|
|
"
|
|
EXTRA_OECONF:class-native = "\
|
|
--disable-tcl \
|
|
"
|
|
CFLAGS:append:class-target = " -D_typ_ssize_t=1 -D_long_double=1"
|
|
CFLAGS:append:class-nativesdk = " -D_typ_ssize_t=1 -D_long_double=1"
|
|
do_configure:prepend() {
|
|
cd ${S}
|
|
# create version.m4 and ignore libtoolize errors
|
|
./autogen.sh NOCONFIG || true
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
# graphviz-setup.sh must be executed at SDK installation
|
|
install -d ${D}${SDKPATHNATIVE}/post-relocate-setup.d
|
|
install -m 0755 ${WORKDIR}/graphviz-setup.sh ${D}${SDKPATHNATIVE}/post-relocate-setup.d
|
|
}
|
|
FILES:${PN}:class-nativesdk += "${SDKPATHNATIVE}"
|
|
|
|
# create /usr/lib/graphviz/config6
|
|
graphviz_sstate_postinst() {
|
|
mkdir -p ${SYSROOT_DESTDIR}${bindir}
|
|
dest=${SYSROOT_DESTDIR}${bindir}/postinst-${PN}
|
|
echo '#!/bin/sh' > $dest
|
|
echo '' >> $dest
|
|
echo 'dot -c' >> $dest
|
|
chmod 0755 $dest
|
|
}
|
|
SYSROOT_PREPROCESS_FUNCS:append:class-native = " graphviz_sstate_postinst"
|
|
|
|
pkg_postinst:${PN} () {
|
|
if [ -n "$D" ]; then
|
|
if ${@bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', 'true', 'false', d)}; then
|
|
${@qemu_run_binary(d, '$D', '${bindir}/dot')} -c
|
|
fi
|
|
else
|
|
dot -c
|
|
fi
|
|
}
|
|
|
|
pkg_postrm:${PN} () {
|
|
rm -f $D${libdir}/graphviz/config*
|
|
rmdir --ignore-fail-on-non-empty $D${libdir}/graphviz
|
|
}
|
|
|
|
PACKAGE_WRITE_DEPS += "qemu-native"
|
|
|
|
PACKAGES =+ "${PN}-python ${PN}-perl ${PN}-demo"
|
|
|
|
FILES:${PN}-python += "${PYTHON_SITEPACKAGES_DIR}/ ${libdir}/graphviz/python/"
|
|
FILES:${PN}-perl += "${libdir}/perl5/*/vendor_perl/ ${libdir}/graphviz/perl/"
|
|
FILES:${PN}-demo += "${datadir}/graphviz/demo/"
|
|
|
|
RDEPENDS:${PN}-perl += "perl"
|
|
RDEPENDS:${PN}-python += "python3"
|
|
RDEPENDS:${PN}-demo += "python3 perl"
|
|
|
|
RRECOMMENDS:${PN} = "liberation-fonts"
|
|
|
|
INSANE_SKIP:${PN}-perl = "dev-so"
|
|
INSANE_SKIP:${PN}-python = "dev-so"
|
|
|
|
FILES_SOLIBSDEV:append = " ${libdir}/graphviz/lib*${SOLIBSDEV}"
|
|
|
|
RRECOMMENDS:${PN} = "liberation-fonts"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|