mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-09 17:33:30 +00:00
8c4bbc148b
iwd and ell need to be updated in sync. This is regularly neglected. Also the fact that they reside in different layers compicates the update process. Beside iwd, there are not a lot of consumers for ell. Building with internal ell makes iwd updates easier Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "Wireless daemon for Linux"
|
|
HOMEPAGE = "https://iwd.wiki.kernel.org/"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fb504b67c50331fc78734fed90fb0e09"
|
|
|
|
DEPENDS = "dbus"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/linux/network/wireless/${BP}.tar.xz \
|
|
file://0001-build-Use-abs_top_srcdir-instead-of-abs_srcdir-for-e.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "86827b97cb5b19ddecce36568c59378da2fae8cf37a0e2b9eacd1269f24c6f8e"
|
|
|
|
inherit autotools manpages pkgconfig python3native systemd
|
|
|
|
PACKAGECONFIG ??= " \
|
|
client \
|
|
monitor \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
"
|
|
PACKAGECONFIG[client] = "--enable-client,--disable-client,readline"
|
|
PACKAGECONFIG[monitor] = "--enable-monitor,--disable-monitor"
|
|
PACKAGECONFIG[manpages] = "--enable-manual-pages,--disable-manual-pages,python3-docutils-native"
|
|
PACKAGECONFIG[wired] = "--enable-wired,--disable-wired"
|
|
PACKAGECONFIG[ofono] = "--enable-ofono,--disable-ofono"
|
|
PACKAGECONFIG[systemd] = "--with-systemd-unitdir=${systemd_system_unitdir},--disable-systemd-service,systemd"
|
|
|
|
SYSTEMD_SERVICE:${PN} = " \
|
|
iwd.service \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'wired', 'ead.service', '', d)} \
|
|
"
|
|
|
|
do_configure:prepend() {
|
|
install -d ${S}/build-aux
|
|
}
|
|
|
|
do_install:append() {
|
|
# If client and monitor are disabled, bindir is empty, causing a QA error
|
|
rmdir --ignore-fail-on-non-empty ${D}/${bindir}
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${nonarch_libdir}/modules-load.d \
|
|
${systemd_unitdir}/network \
|
|
"
|
|
|
|
RDEPENDS:${PN} = "dbus"
|
|
|
|
RRECOMMENDS:${PN} = "\
|
|
kernel-module-pkcs7-message \
|
|
kernel-module-pkcs8-key-parser \
|
|
kernel-module-x509-key-parser \
|
|
"
|