mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-10-01 23:39:36 +00:00
17e3e9b8c2
Release notes: https://github.com/HDFGroup/hdf5/blob/hdf5_1.14.4.3/release_docs/RELEASE.txt License update: link update from https://raw.githubusercontent.com/hdfgroup/hdf5/develop/COPYING_LBNL_HDF5 to https://raw.githubusercontent.com/hdfgroup/hdf5/hdf5_1_14/COPYING_LBNL_HDF5. Upstream has only Released tar file extension is .gz so SRC_URI tar file extension changed from .bz2 to .gz Fixes File /usr/lib/libhdf5.settings in package hdf5 contains reference to TMPDIR File /usr/src/debug/hdf5/1.14.4-3/src/H5build_settings.c in package hdf5-src contains reference to TMPDIR [buildpaths] - Running H5make_libsettings is no longer required for cross-compiling The functionality of H5make_libsettings is now handled via template files, so H5make_libsettings has been removed. - Running H5detect is no longer required for cross-compiling The functionality of H5detect is now exercised at library startup, so H5detect has been removed Rework the patch 0001-cmake-remove-build-flags.patch to fix the build path issue. Signed-off-by: Yogita Urade <yogita.urade@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
66 lines
2.2 KiB
BlitzBasic
66 lines
2.2 KiB
BlitzBasic
SUMMARY = "Management suite for extremely large and complex data collections"
|
|
DESCRIPTION = "Unique technology suite that makes possible the management of \
|
|
extremely large and complex data collections"
|
|
HOMEPAGE = "https://www.hdfgroup.org/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "HDF5"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=adebb1ecf1b3b80c13359e18ef67301e"
|
|
|
|
inherit cmake siteinfo qemu multilib_header multilib_script
|
|
|
|
DEPENDS += "qemu-native zlib"
|
|
|
|
SRC_URI = " \
|
|
https://support.hdfgroup.org/ftp/HDF5/releases/hdf5-1.14/hdf5-1.14.4/src/${BPN}-${PV}.tar.gz \
|
|
file://0002-Remove-suffix-shared-from-shared-library-name.patch \
|
|
file://0001-cmake-remove-build-flags.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "019ac451d9e1cf89c0482ba2a06f07a46166caf23f60fea5ef3c37724a318e03"
|
|
|
|
FILES:${PN} += "${libdir}/libhdf5.settings ${datadir}/*"
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DHDF5_INSTALL_CMAKE_DIR=${libdir}/cmake \
|
|
-DCMAKE_INSTALL_PREFIX='${prefix}' \
|
|
-DHDF5_INSTALL_LIB_DIR='${baselib}' \
|
|
"
|
|
EXTRA_OECMAKE:prepend:class-target = "-DCMAKE_CROSSCOMPILING_EMULATOR=${WORKDIR}/qemuwrapper "
|
|
|
|
gen_emu() {
|
|
# Write out a qemu wrapper that will be used by cmake
|
|
# so that it can run target helper binaries through that.
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
|
|
cat > ${WORKDIR}/qemuwrapper << EOF
|
|
#!/bin/sh
|
|
$qemu_binary "\$@"
|
|
EOF
|
|
chmod +x ${WORKDIR}/qemuwrapper
|
|
}
|
|
|
|
do_unpack[postfuncs] += "gen_emu"
|
|
|
|
MULTILIB_SCRIPTS += "${PN}:${bindir}/h5cc \
|
|
${PN}:${bindir}/h5hlcc \
|
|
"
|
|
|
|
do_configure:append() {
|
|
sed -i -e 's|${WORKDIR}||g' ${B}/src/libhdf5.settings
|
|
sed -i -e 's|${WORKDIR}||g' ${B}/src/H5build_settings.c
|
|
}
|
|
|
|
do_install:append() {
|
|
# Used for generating config files on target
|
|
oe_multilib_header H5pubconf.h
|
|
# remove the buildpath
|
|
sed -i -e 's|${RECIPE_SYSROOT}||g' ${D}${libdir}/pkgconfig/hdf5.pc
|
|
sed -i -e 's|${RECIPE_SYSROOT}||g' ${D}${libdir}/cmake/hdf5-targets.cmake
|
|
sed -i -e 's|${RECIPE_SYSROOT_NATIVE}||g' ${D}${bindir}/h5hlcc
|
|
sed -i -e 's|${RECIPE_SYSROOT_NATIVE}||g' ${D}${bindir}/h5cc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
# h5fuse.sh script needs bash
|
|
RDEPENDS:${PN} += "bash"
|