mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-10-01 22:34:04 +00:00
aa4c35b421
Changelog: =========== - fix checkpatch warnings - Use the right dev_t decoding for diskerror handler - Add new modules supported by HiSilicon common section - Fix some static check warning - Fix few compilation warnings in non standard hisilicon code - Fix some compilation alarms in ras-record.h. - ras-mc-ctl: Update logging of CXL memory module data to align with CXL spec rev 3.1 - ras-mc-ctl: Update logging of CXL DRAM event data to align with CXL spec rev 3.1 - ras-mc-ctl: Update logging of CXL general media event data to align with CXL spec rev 3.1 - ras-mc-ctl: Update logging of common event data to align with CXL spec rev 3.1 - ras-mc-ctl: Fix logging of memory event type in CXL DRAM error table - cxl: Update memory module event to CXL spec rev 3.1 - cxl: Update CXL DRAM event to CXL spec rev 3.1 - cxl: Update CXL general media event to CXL spec rev 3.1 - cxl: Add Component Identifier formatting for CXL spec rev 3.1 - cxl: Update common event to CXL spec rev 3.1 - cxl: Add automatic indexing for storing CXL fields in SQLite database - cxl: Fix mismatch in region field's name with kernel DRAM trace event - cxl: Fix logging of memory event type of DRAM trace event - Fix for parsing error when trace event's format file is larger than PAGE_SIZE - Add page offline support for cxl memory - for ASRock X370 Taichi - for ASRock X570 Creator - for ASRock X570S PG Riptide - mce: decode io port for bus error - arm: do not print error msg if field not found - add DE error type for AMD - Fix the display format of JaguarMicro vendor no standard errors Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
52 lines
2.1 KiB
BlitzBasic
52 lines
2.1 KiB
BlitzBasic
DESCRIPTION = "Tools to provide a way to get Platform Reliability, Availability and Serviceability (RAS) reports made via the Kernel tracing events"
|
|
HOMEPAGE = "https://github.com/mchehab/rasdaemon"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d3070efe0afa3dc41608bd82c00bb0dc"
|
|
|
|
SRC_URI = "git://github.com/mchehab/rasdaemon.git;branch=master;protocol=https \
|
|
file://rasdaemon.service \
|
|
file://init"
|
|
|
|
SRCREV = "db0870edd2919f4f4d0101843136bcae92ab0743"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "libtraceevent"
|
|
RDEPENDS:${BPN} = "perl perl-module-file-basename perl-module-file-find perl-module-file-spec perl-module-getopt-long \
|
|
perl-module-posix perl-module-file-glob libdbi-perl libdbd-sqlite-perl"
|
|
|
|
inherit autotools pkgconfig update-rc.d systemd
|
|
|
|
PACKAGECONFIG ??= "sqlite3 mce aer extlog devlink diskerror"
|
|
PACKAGECONFIG[sqlite3] = "--enable-sqlite3,--disable-sqlite3,sqlite3"
|
|
PACKAGECONFIG[mce] = "--enable-mce,--disable-mce"
|
|
PACKAGECONFIG[aer] = "--enable-aer,--disable-aer"
|
|
PACKAGECONFIG[extlog] = "--enable-extlog,--disable-extlog"
|
|
PACKAGECONFIG[devlink] = "--enable-devlink,--disable-devlink"
|
|
PACKAGECONFIG[diskerror] = "--enable-diskerror,--disable-diskerror"
|
|
PACKAGECONFIG[arm] = "--enable-arm,--disable-arm"
|
|
PACKAGECONFIG[hisi-ns-decode] = "--enable-hisi-ns-decode,--disable-hisi-ns-decode"
|
|
PACKAGECONFIG[non-standard] = "--enable-non-standard,--disable-non-standard"
|
|
PACKAGECONFIG[abrt-report] = "--enable-abrt-report,--disable-abrt-report"
|
|
|
|
DEPENDS:append:libc-musl = " argp-standalone"
|
|
LDFLAGS:append:libc-musl = " -largp"
|
|
|
|
do_install:append() {
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 755 ${UNPACKDIR}/init ${D}${sysconfdir}/init.d/rasdaemon
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${UNPACKDIR}/rasdaemon.service ${D}${systemd_unitdir}/system
|
|
}
|
|
|
|
FILES:${PN} += "${sbindir}/rasdaemon \
|
|
${sysconfdir}/init.d \
|
|
${systemd_unitdir}/system/rasdaemon.service"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "rasdaemon.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME:${PN} = "rasdaemon"
|
|
INITSCRIPT_PARAMS:${PN} = "defaults 89"
|