mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-08-13 07:15:36 +00:00
77397ccbb9
Added version bump to fix the ipmitool build issue.
Build failure details available as part of this commit.
bf774149ae
Additional commit included in this version bump are below.
Alexander Amelkin (1):
man: Remove duplicate description for -b and -B
Alexander Filippov (3):
Remove trailing spaces
replace HAS_PRAGMA_PACK macros
imb: refix structure packing
Howitzer105mm (4):
Establish a uniform structure packing syntax
ipmievd: Eliminate a possible command line overrun (#27)
open: Eliminate buffer overrun (#24)
lan: Clean compile time warning from LAN authentication (#22)
István Donkó (1):
doc: fix a small typo in `print_user_usage`
Johnathan Mantey (1):
fru: Fix a typo causing compilation to fail (#37)
Miao Wang (1):
lan: fix lan print fails on unsupported parameters
bbradley (1):
chassis: Partial revert of 6e037d6bfbb (#19)
Signed-off-by: Jayanth Othayoth <ojayanth@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
66 lines
2.8 KiB
BlitzBasic
66 lines
2.8 KiB
BlitzBasic
SUMMARY = "Utility for IPMI control"
|
|
DESCRIPTION = "This package contains a utility for interfacing with devices that support \
|
|
the Intelligent Platform Management Interface specification. IPMI is \
|
|
an open standard for machine health, inventory, and remote power control. \
|
|
\
|
|
This utility can communicate with IPMI-enabled devices through either a \
|
|
kernel driver such as OpenIPMI or over the RMCP LAN protocol defined in \
|
|
the IPMI specification. IPMIv2 adds support for encrypted LAN \
|
|
communications and remote Serial-over-LAN functionality. \
|
|
\
|
|
It provides commands for reading the Sensor Data Repository (SDR) and \
|
|
displaying sensor values, displaying the contents of the System Event \
|
|
Log (SEL), printing Field Replaceable Unit (FRU) information, reading and \
|
|
setting LAN configuration, and chassis power control. \
|
|
"
|
|
|
|
HOMEPAGE = "http://codeberg.org/IPMITool/ipmitool"
|
|
SECTION = "kernel/userland"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=9aa91e13d644326bf281924212862184"
|
|
|
|
DEPENDS = "openssl readline ncurses"
|
|
SRCREV = "bf774149ae7f74c12164a5b021b23520c5ca4016"
|
|
SRC_URI = "git://codeberg.org/ipmitool/ipmitool;protocol=https;branch=master \
|
|
${IANA_ENTERPRISE_NUMBERS} \
|
|
file://0001-csv-revision-Drop-the-git-revision-info.patch \
|
|
"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "IPMITOOL_(?P<pver>\d+(_\d+)+)"
|
|
|
|
IANA_ENTERPRISE_NUMBERS ?= ""
|
|
|
|
# Add these via bbappend if this database is needed by the system
|
|
#IANA_ENTERPRISE_NUMBERS = "http://www.iana.org/assignments/enterprise-numbers.txt;name=iana-enterprise-numbers;downloadfilename=iana-enterprise-numbers"
|
|
#SRC_URI[iana-enterprise-numbers.sha256sum] = "cdd97fc08325667434b805eb589104ae63f7a9eb720ecea73cb55110b383934c"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
do_install:append() {
|
|
if [ -e ${UNPACKDIR}/iana-enterprise-numbers ]; then
|
|
install -Dm 0755 ${UNPACKDIR}/iana-enterprise-numbers ${D}${datadir}/misc/enterprise-numbers
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-ipmievd"
|
|
FILES:${PN}-ipmievd += "${sbindir}/ipmievd"
|
|
FILES:${PN} += "${datadir}/misc"
|
|
|
|
# --disable-dependency-tracking speeds up the build
|
|
# --enable-file-security adds some security checks
|
|
# --disable-intf-free disables FreeIPMI support - we don't want to depend on
|
|
# FreeIPMI libraries, FreeIPMI has its own ipmitoool-like utility.
|
|
# --disable-registry-download prevents the IANA numbers from being fetched
|
|
# at build time, as it is not repeatable.
|
|
#
|
|
EXTRA_OECONF = "--disable-dependency-tracking --enable-file-security --disable-intf-free \
|
|
--disable-registry-download \
|
|
"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/766896/
|
|
# git/lib/ipmi_fru.c:1556:41: error: initialization of 'struct fru_multirec_mgmt *' from incompatible pointer type 'struct fru_multirect_mgmt *' [-Wincompatible-pointer-types]
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|