mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
1b8080375d
Also disable running clang-tidy on the code. On one hand the cmake script is trying to run the target version of it, and on the other hand it is not needed for compiling it, it is intended for upstream developers. Changelog: https://github.com/transmission/transmission/releases/tag/4.1.1 Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
67 lines
2.8 KiB
BlitzBasic
67 lines
2.8 KiB
BlitzBasic
DESCRIPTION = "Transmission is a fast, easy, and free BitTorrent client"
|
|
SECTION = "network"
|
|
HOMEPAGE = "https://transmissionbt.com/"
|
|
LICENSE = "MIT & GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d54f298b276b8cc5f20168e43a0e8103"
|
|
|
|
DEPENDS = "curl libevent libpsl gnutls openssl libtool intltool-native glib-2.0-native"
|
|
RDEPENDS:${PN}-web = "${PN}"
|
|
|
|
SRC_URI = " \
|
|
gitsm://github.com/transmission/transmission;branch=4.1.x;protocol=https;tag=${PV} \
|
|
file://0001-bump-cmake-to-3.10.patch;patchdir=third-party/libb64 \
|
|
file://0001-Increase-minimum-CMake-version-to-3.10.patch;patchdir=third-party/libdeflate \
|
|
file://transmission-daemon \
|
|
"
|
|
|
|
# Transmission release 4.1.0
|
|
SRCREV = "56442e2929cf4e9e20c8604a229e99fbb352190c"
|
|
|
|
|
|
inherit cmake gettext update-rc.d pkgconfig systemd mime-xdg
|
|
|
|
LDFLAGS:append:riscv32 = " -latomic"
|
|
|
|
PACKAGECONFIG = "${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'gtk', '', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','systemd','systemd','',d)}"
|
|
|
|
PACKAGECONFIG[gtk] = "-DENABLE_GTK=ON,-DENABLE_GTK=OFF,gtk4 gtkmm4,"
|
|
PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF,systemd,"
|
|
|
|
EXTRA_OECMAKE = "-DRUN_CLANG_TIDY=OFF"
|
|
|
|
# Weak default values for transmission user and group
|
|
# Change them in bbappend if needed
|
|
TRANSMISSION_USER ??= "root"
|
|
TRANSMISSION_GROUP ??= "root"
|
|
|
|
do_install:append() {
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
|
|
sed -i '/USERNAME=/c\USERNAME=${TRANSMISSION_USER}' ${UNPACKDIR}/transmission-daemon
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 0744 ${UNPACKDIR}/transmission-daemon ${D}${sysconfdir}/init.d/
|
|
chown ${TRANSMISSION_USER}:${TRANSMISSION_GROUP} ${D}${sysconfdir}/init.d/transmission-daemon
|
|
fi
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
sed -i '/User=/c\User=${TRANSMISSION_USER}' ${B}/daemon/transmission-daemon.service
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${B}/daemon/transmission-daemon.service ${D}${systemd_unitdir}/system
|
|
fi
|
|
}
|
|
|
|
PACKAGES += "${PN}-gtk ${PN}-client ${PN}-web"
|
|
|
|
FILES:${PN}-client = "${bindir}/transmission-remote ${bindir}/transmission-cli ${bindir}/transmission-create ${bindir}/transmission-show ${bindir}/transmission-edit"
|
|
FILES:${PN}-gtk += "${bindir}/transmission-gtk ${datadir}/icons ${datadir}/applications ${datadir}/pixmaps ${datadir}/metainfo"
|
|
FILES:${PN}-web = "${datadir}/transmission/web ${datadir}/transmission/public_html"
|
|
FILES:${PN} = "${bindir}/transmission-daemon ${sysconfdir}/init.d/transmission-daemon ${datadir}/appdata"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "transmission-daemon.service"
|
|
|
|
# Script transmission-daemon following the guidelines in:
|
|
# https://trac.transmissionbt.com/wiki/Scripts/initd
|
|
INITSCRIPT_PACKAGES = "transmission-daemon"
|
|
INITSCRIPT_NAME = "transmission-daemon"
|
|
INITSCRIPT_PARAMS = "start 99 5 3 2 . stop 10 0 1 6 ."
|