mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-03 07:26:30 +00:00
caca326d97
Add run-ptest to run the 7 tests provided by jq. In do_install_ptest, add a soft link to jq in the ptest directory to avoid having to patch the jq setup script. While the jq tests can use valgrind, it is out of scope for integration testing. Signed-off-by: Zheng Qiu <zheng.qiu@windriver.com> Signed-off-by: Randy MacLeod <randy.macleod@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
41 lines
1.5 KiB
BlitzBasic
41 lines
1.5 KiB
BlitzBasic
SUMMARY = "Lightweight and flexible command-line JSON processor"
|
|
DESCRIPTION = "jq is like sed for JSON data, you can use it to slice and \
|
|
filter and map and transform structured data with the same \
|
|
ease that sed, awk, grep and friends let you play with text."
|
|
HOMEPAGE = "https://stedolan.github.io/jq/"
|
|
BUGTRACKER = "https://github.com/stedolan/jq/issues"
|
|
SECTION = "utils"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2814b59e00e7918c864fa3b6bbe049b4"
|
|
|
|
PV = "1.6+git${SRCPV}"
|
|
SRC_URI = "git://github.com/stedolan/jq;protocol=https;branch=master \
|
|
file://0001-configure-Pass-_XOPEN_SOURCE-when-checking-for-strpt.patch \
|
|
file://0002-builtin-Replace-_BSD_SOURCE-with-_DEFAULT_SOURCE.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "cff5336ec71b6fee396a95bb0e4bea365e0cd1e8"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
PACKAGECONFIG ?= "oniguruma"
|
|
|
|
PACKAGECONFIG[docs] = "--enable-docs,--disable-docs,ruby-native"
|
|
PACKAGECONFIG[maintainer-mode] = "--enable-maintainer-mode,--disable-maintainer-mode,flex-native bison-native"
|
|
PACKAGECONFIG[oniguruma] = "--with-oniguruma,--without-oniguruma,onig"
|
|
|
|
EXTRA_OECONF += " \
|
|
--disable-valgrind \
|
|
"
|
|
|
|
do_install_ptest() {
|
|
cp -rf ${B}/tests ${D}${PTEST_PATH}
|
|
cp -rf ${B}/.libs ${D}${PTEST_PATH}
|
|
# libjq.so.* is packaged in the main jq component, so remove it from ptest
|
|
rm -f ${D}${PTEST_PATH}/.libs/libjq.so.*
|
|
ln -sf ${bindir}/jq ${D}${PTEST_PATH}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|