mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-07 05:27:39 +00:00
94d2364152
0001-nss-nspr-fix-for-multilib.patch
change-finding-path-of-nss.patch
ensure-search-path-non-host.patch
fix-ltmain.sh.patch
refreshed for 1.3.3
Changelog
========
-Disabled KeyValue and DEREncodedKeyValue XML nodes by default. Use the
'--enabled-key-data' option for the xmlsec command line utility or update
the 'keyInfoCtx->enabledKeyData' parameter if you need to re-enable these
nodes (also see question 3.5 in the FAQ).
-Removed '--enable-size-t' ('size_t' for MSVC builds) option and made
'xmlSecSize' to always be the same as 'size_t'.
-Removed previously deprecated functions, defines, etc.
-Fixed build for libxml2 v2.12.0.
-Removed support for OpenSSL 1.1.0 (end of life in Aug 2016).
The minimum OpenSSL supported version is 1.1.1; the version 3.0.0 or greater is recommended.
-Added runtime check for the enabled algorithms in NSS.
-Removed NT4 support.
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
68 lines
2.2 KiB
BlitzBasic
68 lines
2.2 KiB
BlitzBasic
SUMMARY = "XML Security Library is a C library based on LibXML2"
|
|
DESCRIPTION = "\
|
|
XML Security Library is a C library based on \
|
|
LibXML2 and OpenSSL. The library was created with a goal to support major \
|
|
XML security standards "XML Digital Signature" and "XML Encryption". \
|
|
"
|
|
HOMEPAGE = "http://www.aleksey.com/xmlsec/"
|
|
DEPENDS = "libtool libxml2 libxslt zlib"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=352791d62092ea8104f085042de7f4d0"
|
|
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "http://www.aleksey.com/xmlsec/download/${BP}.tar.gz \
|
|
file://fix-ltmain.sh.patch \
|
|
file://change-finding-path-of-nss.patch \
|
|
file://makefile-ptest.patch \
|
|
file://xmlsec1-examples-allow-build-in-separate-dir.patch \
|
|
file://0001-nss-nspr-fix-for-multilib.patch \
|
|
file://run-ptest \
|
|
file://ensure-search-path-non-host.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "ab5b9a9ffd6960f46f7466d9d91f174ec37e8c31989237ba6b9eacdd816464f2"
|
|
|
|
inherit autotools-brokensep ptest pkgconfig
|
|
|
|
#CFLAGS += "-I${STAGING_INCDIR}/nss3"
|
|
#CPPFLAGS += "-I${STAGING_INCDIR}/nss3"
|
|
|
|
PACKAGECONFIG ??= "gnutls libgcrypt nss openssl des"
|
|
PACKAGECONFIG[gnutls] = ",,gnutls"
|
|
PACKAGECONFIG[libgcrypt] = ",,libgcrypt"
|
|
PACKAGECONFIG[nss] = "--with-nss=${STAGING_DIR_HOST} --with-nspr=${STAGING_DIR_HOST},--with-nss=no --with-nspr=no,nss nspr"
|
|
PACKAGECONFIG[openssl] = ",,openssl"
|
|
PACKAGECONFIG[des] = ",--disable-des,,"
|
|
|
|
# these can be dynamically loaded with xmlSecCryptoDLLoadLibrary()
|
|
FILES_SOLIBSDEV = "${libdir}/libxmlsec1.so"
|
|
FILES:${PN} += "${libdir}/libxmlsec1-*.so"
|
|
INSANE_SKIP:${PN} = "dev-so"
|
|
|
|
FILES:${PN}-dev += "${libdir}/xmlsec1Conf.sh"
|
|
FILES:${PN}-dbg += "${PTEST_PATH}/.debug/*"
|
|
|
|
RDEPENDS:${PN}-ptest += "${PN}-dev"
|
|
INSANE_SKIP:${PN}-ptest += "dev-deps"
|
|
|
|
PTEST_EXTRA_ARGS = "top_srcdir=${S} top_builddir=${B}"
|
|
|
|
do_compile_ptest () {
|
|
oe_runmake -C ${S}/examples ${PTEST_EXTRA_ARGS} all
|
|
}
|
|
|
|
do_install:append() {
|
|
for i in ${bindir}/xmlsec1-config ${libdir}/xmlsec1Conf.sh \
|
|
${libdir}/pkgconfig/xmlsec1-openssl.pc; do
|
|
sed -i -e "s@${RECIPE_SYSROOT}@@g" ${D}$i
|
|
done
|
|
}
|
|
|
|
do_install_ptest () {
|
|
oe_runmake -C ${S}/examples DESTDIR=${D}${PTEST_PATH} ${PTEST_EXTRA_ARGS} install-ptest
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|