mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-04 03:23:48 +00:00
f4533380c8
The dracut modules will be installed to /usr/lib64 while building 64bit targets with multilib enabled, this causes runtime errors: dracut: Cannot find /usr/lib/dracut/dracut-functions.sh. dracut: Are you running from a git checkout? dracut: Try passing -l as an argument to /usr/bin/dracut The dracut modules, 50-dracut.install and 51-dracut-rescue.install must be installed to /usr/lib as Fedora 20 does. Signed-off-by: Wenzong Fan <wenzong.fan@windriver.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
62 lines
2.0 KiB
BlitzBasic
62 lines
2.0 KiB
BlitzBasic
SUMMARY = "Initramfs generator using udev"
|
|
DESCRIPTION = "Dracut is an event driven initramfs infrastructure. dracut (the tool) is used to create an initramfs image by copying tools and files from an installed system and combining it with the dracut framework, usually found in /usr/lib/dracut/modules.d."
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
PE = "1"
|
|
PV = "043+git${SRCREV}"
|
|
|
|
# v043 tag
|
|
SRCREV = "eab03540cd695d940062af5b55c02e8829aaa526"
|
|
SRC_URI = "git://git.kernel.org/pub/scm/boot/dracut/dracut.git"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF = "--prefix=${prefix} \
|
|
--libdir=${prefix}/lib \
|
|
--datadir=${datadir} \
|
|
--sysconfdir=${sysconfdir} \
|
|
--sbindir=${sbindir} \
|
|
--disable-documentation \
|
|
--bindir=${bindir} \
|
|
--includedir=${includedir} \
|
|
--localstatedir=${localstatedir} \
|
|
"
|
|
|
|
# RDEPEND on systemd optionally
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_unitdir}/system/,,,systemd"
|
|
|
|
EXTRA_OEMAKE += 'libdir=${prefix}/lib'
|
|
|
|
do_configure() {
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-bash-completion"
|
|
|
|
FILES_${PN}-bash-completion = "${datadir}/bash-completion"
|
|
|
|
FILES_${PN} += "${prefix}/lib/kernel \
|
|
${prefix}/lib/dracut \
|
|
${systemd_unitdir} \
|
|
"
|
|
FILES_${PN}-dbg += "${prefix}/lib/dracut/.debug"
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/dracut.conf"
|
|
|
|
RDEPENDS_${PN} = "findutils cpio util-linux-blkid util-linux-getopt bash ldd"
|
|
RDEPENDS_${PN}-bash-completion = "bash-completion"
|
|
|
|
# This could be optimized a bit, but let's avoid non-booting systems :)
|
|
RRECOMMENDS_${PN} = " \
|
|
kernel-modules \
|
|
busybox \
|
|
coreutils \
|
|
"
|