mirror of
git://git.openembedded.org/meta-openembedded
synced 2025-12-31 13:38:06 +00:00
31519530f3
With: https://lists.openembedded.org/g/bitbake-devel/message/17508 there are WARNINGs like: WARNING: meta-oe/meta-filesystems/recipes-filesystems/smbnetfs/smbnetfs_git.bb: meta-oe/meta-filesystems/recipes-filesystems/smbnetfs/smbnetfs_git.bb:9 has a lack of whitespace around the assignment: 'HOMEPAGE ="http://sourceforge.net/projects/smbnetfs"' WARNING: meta-oe/meta-filesystems/recipes-filesystems/zfs/zfs_2.2.5.bb: meta-oe/meta-filesystems/recipes-filesystems/zfs/zfs_2.2.5.bb:5 has a lack of whitespace around the assignment: 'HOMEPAGE ="https://github.com/openzfs/zfs"' WARNING: meta-oe/meta-filesystems/dynamic-layers/meta-python/recipes-support/gpiod-sysfs-proxy/gpiod-sysfs-proxy_0.1.2.bb: meta-oe/meta-filesystems/dynamic-layers/meta-python/recipes-support/gpiod-sysfs-proxy/gpiod-sysfs-proxy_0.1.2.bb:27 has a lack of whitespace around the assignment: 'export MOUNTPOINT="${@bb.utils.contains('PACKAGECONFIG', 'sys-class-mount', '/sys/class/gpio', '/run/gpio', d)}"' Signed-off-by: Martin Jansa <martin.jansa@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
88 lines
3.2 KiB
BlitzBasic
88 lines
3.2 KiB
BlitzBasic
SUMMARY = "OpenZFS on Linux and FreeBSD"
|
|
DESCRIPTION = "OpenZFS on Linux and FreeBSD"
|
|
LICENSE = "CDDL-1.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=7087caaf1dc8a2856585619f4a787faa"
|
|
HOMEPAGE = "https://github.com/openzfs/zfs"
|
|
|
|
SRCREV = "33174af15112ed5c53299da2d28e763b0163f428"
|
|
SRC_URI = "git://github.com/openzfs/zfs;protocol=https;branch=zfs-2.2-release \
|
|
file://0001-Define-strndupa-if-it-does-not-exist.patch \
|
|
file://aaf28a4630af60496c9d33db1d06a7d7d8983422.patch \
|
|
file://0001-fs-tests-cmd-readmmap-Replace-uint_t-with-uint32_t.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# Using both 'module' and 'autotools' classes seems a bit odd, they both
|
|
# define a do_compile function.
|
|
# That's why we opt for module-base, also this prevents module splitting.
|
|
inherit module-base pkgconfig autotools bash-completion
|
|
|
|
DEPENDS = "virtual/kernel zlib util-linux libtirpc openssl curl"
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd sysvinit', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[pam] = "--enable-pam --with-pamconfigsdir=${datadir}/pam-configs --with-pammoduledir=${base_libdir}/security, --disable-pam"
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,"
|
|
PACKAGECONFIG[sysvinit] = "--enable-sysvinit,--disable-sysvinit,"
|
|
|
|
EXTRA_OECONF:append = " \
|
|
--disable-pyzfs \
|
|
--with-linux=${STAGING_KERNEL_DIR} --with-linux-obj=${STAGING_KERNEL_BUILDDIR} \
|
|
--with-mounthelperdir=${base_sbin} \
|
|
--with-udevdir=${base_libdir}/udev \
|
|
--with-systemdunitdir=${systemd_system_unitdir} \
|
|
--with-systemdgeneratordir=${nonarch_base_libdir}/systemd/system-generators \
|
|
--with-systemdpresetdir=${nonarch_base_libdir}/systemd/system-preset \
|
|
--with-systemdmodulesloaddir=${sysconfdir}/module-load.d \
|
|
--without-dracutdir --enable-linux-builtin \
|
|
"
|
|
|
|
# Reproducibility: Force target distribution ("vendor") to Debian to match
|
|
# default values for things like: NFS server service name, bash completion
|
|
# path, configuration files, ...
|
|
# The Debian values do match the OpenEmbedded ones.
|
|
EXTRA_OECONF:append = " --with-vendor=debian"
|
|
|
|
EXTRA_OEMAKE:append = " \
|
|
INSTALL_MOD_PATH=${D}${root_prefix} \
|
|
"
|
|
|
|
do_install:append() {
|
|
# /usr/share/zfs contains the zfs-tests folder which we do not need:
|
|
rm -rf ${D}${datadir}/zfs
|
|
|
|
rm -rf ${D}${datadir}/initramfs-tools
|
|
}
|
|
|
|
FILES:${PN} += "\
|
|
${nonarch_base_libdir}/modules \
|
|
${systemd_system_unitdir} \
|
|
${nonarch_base_libdir}/systemd/system-generators \
|
|
${nonarch_base_libdir}/systemd/system-preset \
|
|
${sysconfdir}/modules-load.d/${BPN}.conf \
|
|
${sysconfdir}/default/${BPN} \
|
|
${sysconfdir}/sudoers.d/${BPN} \
|
|
${sysconfdir}/${BPN} \
|
|
${base_libdir}/udev \
|
|
${sbindir} \
|
|
${bindir} \
|
|
${libexecdir}/${BPN} \
|
|
${libdir} \
|
|
${datadir}/pam-configs \
|
|
${base_libdir}/security \
|
|
"
|
|
|
|
FILES:${PN}-dev += "\
|
|
${prefix}/src/zfs-${PV} \
|
|
${prefix}/src/spl-${PV} \
|
|
"
|
|
# Not yet ported to rv32
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
# conflicting definition of ABS macro from asm/asm.h from kernel
|
|
COMPATIBLE_HOST:mips = "null"
|
|
# FTBFS on aarch64 with 6.2+ kernel see https://github.com/openzfs/zfs/issues/14555
|
|
COMPATIBLE_HOST:aarch64 = "null"
|