mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-06-14 04:01:42 +00:00
559ec62e99
0001-fix-swig-avoid-clang-GNUC-pragma-block-before-_lib.h.patch removed since it's included in 0.48.0 Changelog: ============= - doc: another move this time to Codeberg (and communication to Matrix) - test(smime): parametrize test_write_pkcs7_der - test(smime): fix test_signEncryptDecryptVerify - fix(util): return bytes from passphrase callbacks - fix(SSL.Checker): add IDN Chinese name - test(ssl): add IDN certificate fixture coverage - test(ssl): cover IDN hostname matching in Checker - doc: update expected Name format in migration guide - fix(smime): S/MIME signature verification for Outlook and Thunderbird - fix(provider): handle OSSL_STORE_INFO_PUBKEY compat. for OpenSSL < 3.2 - fix: cast X509_dup in sk_X509_deep_copy to avoid type mismatch - fix(smime): S/MIME signature verification for Outlook and Thunderbird - fix(smime): remove obsolete Python pre-3.6 constructs - ci: run on Codeberg with forgejo_runner - doc: clarify the status of the project - fix(provider): adjust the CI run on Gitea for the older OpenSSL on Debian - fix(evp): narrow digest and BIO pointers for mypy - fix(init): acommodate modern packaging API - doc: IRC channel is on Libera, Ergo was a wrong idea - fix(tests): remove duplicate definition of IS_DEBIAN in test_ssl - fix(test_bio_ssl): fix TLS 1.3 deadlock and add socket timeouts - fix(test_bio_ssl): replace sys.exit() with self.fail() to prevent test process crash - ci: publish to PyPI with Sigstore attestations via Trusted Publishing - fix(authcookie): handle CookieError from Python 3.13.12+ (CVE-2026-0672) - ci(leap): use setup.py bdist_wheel to bypass old pip PEP 517 wrapper - fix(util): replace is_32bit with struct.calcsize and update tests - ci: add FreeBSD SourceHut CI build script - fix(swig): avoid clang GNUC pragma block before _lib.h - fix(provider): don't abuse TemporaryDirectory to be mkdtemp, use that directly. - fix(provider): gate provider APIs for OpenSSL 1.1.1 - feat(provider): add key generation and destruction methods - docs(provider): add comprehensive documentation to Provider module - fix(provider): better exception handling - doc: add a simple AGENTS.md - feat(engine): add availability check, lifecycle helpers, and safer cleanup - doc(engine): Improve documentation and example of using Engine module Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
56 lines
1.9 KiB
BlitzBasic
56 lines
1.9 KiB
BlitzBasic
SUMMARY = "A Python crypto and SSL toolkit"
|
|
HOMEPAGE = "https://gitlab.com/m2crypto/m2crypto"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSES/BSD-2-Clause.txt;md5=8099b0e569f862ece05740aef06c82a2"
|
|
|
|
SRC_URI[sha256sum] = "178e290f558ddf0379aaefd34c0a8ddb21f21502594e588f928dda85f1ad202b"
|
|
|
|
SRC_URI += "file://0001-setup.py-Make-the-cmd-available.patch"
|
|
|
|
CVE_STATUS[CVE-2009-0127] = "disputed: upstream claims there is no bug"
|
|
CVE_STATUS[CVE-2020-25657] = "fixed-version: the used version (0.46.2) contains the fix already"
|
|
|
|
inherit pypi siteinfo python_setuptools_build_meta
|
|
|
|
DEPENDS += "openssl swig-native"
|
|
RDEPENDS:${PN} += "\
|
|
python3-datetime \
|
|
python3-setuptools \
|
|
python3-logging \
|
|
python3-netclient \
|
|
python3-netserver \
|
|
python3-numbers \
|
|
python3-xmlrpc \
|
|
"
|
|
|
|
DISTUTILS_BUILD_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR} -I${STAGING_INCDIR}"
|
|
DISTUTILS_INSTALL_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR}"
|
|
|
|
SWIG_FEATURES ?= "-D__${HOST_ARCH}__ ${@['-D__ILP32__','-D__LP64__'][d.getVar('SITEINFO_BITS') != '32']} -DOPENSSL_NO_FILENAMES"
|
|
|
|
SWIG_FEATURES:append:riscv64 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
|
|
SWIG_FEATURES:append:riscv32 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
|
|
SWIG_FEATURES:append:mipsarch = " -D_MIPS_SZPTR=${SITEINFO_BITS}"
|
|
SWIG_FEATURES:append:powerpc64le = " -D__powerpc64__"
|
|
SWIG_FEATURES:append:x86 = " -D__i386__"
|
|
SWIG_FEATURES:append:x32 = " -D__ILP32__"
|
|
|
|
export SWIG_FEATURES
|
|
|
|
export STAGING_DIR
|
|
|
|
do_configure:prepend:class-target() {
|
|
# workaround for https://github.com/swiftlang/swift/issues/69311
|
|
sed -i "/sys\/types.h/d" ${RECIPE_SYSROOT}${includedir}/openssl/e_os2.h
|
|
}
|
|
|
|
do_install:append() {
|
|
rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/SSL/__pycache__/*.cpython-*.pyc
|
|
rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/__pycache__/*.cpython-*.pyc
|
|
}
|
|
|
|
CVE_PRODUCT = "m2crypto"
|
|
|
|
BBCLASSEXTEND = "native"
|