mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-05-18 21:28:52 +00:00
7142f09407
cpupower is a 'special' recipe since it does "inherit kernelsrc" , which essentially means that it doesn't have its own sources, but reuse the kernel source tree, from virtual/kernel recipe. As such, checking the license file in cpupower recipe does not seem relevant, since it does not fetch anything (kernelsrc has "deltask do_fetch") and the fetching is deferred to the virtual/kernel recipe. so we are basically checking the COPYING file twice. If there was any license issue, it would have been caught by virtual/kernel recipe already. Hence we remove LIC_FILES_CHKSUM like it is done for perf recipe in OE-core in meta/recipes-kernel/perf/perf.bb. It has the nice side effect that BSP layers can use different kernel versions without worrying about any LICENSE checksum changes in between kernel versions. Reported-by: Daniel Díaz <daniel.diaz@linaro.org> Signed-off-by: Nicolas Dechesne <nicolas.dechesne@linaro.org> Signed-off-by: Khem Raj <raj.khem@gmail.com>
36 lines
903 B
BlitzBasic
36 lines
903 B
BlitzBasic
SUMMARY = "Shows and sets processor power related values"
|
|
DESCRIPTION = "cpupower is a collection of tools to examine and tune power \
|
|
saving related features of your processor."
|
|
LICENSE = "GPLv2"
|
|
DEPENDS = "pciutils gettext-native"
|
|
PROVIDES = "virtual/cpupower"
|
|
|
|
inherit kernelsrc kernel-arch bash-completion
|
|
|
|
do_populate_lic[depends] += "virtual/kernel:do_patch"
|
|
|
|
EXTRA_OEMAKE = "-C ${S}/tools/power/cpupower O=${B} CROSS=${TARGET_PREFIX} CC="${CC}" LD="${LD}" AR=${AR} ARCH=${ARCH}"
|
|
|
|
do_configure[depends] += "virtual/kernel:do_shared_workdir"
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
# Do not ship headers
|
|
rm -rf ${D}${includedir}
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
RDEPENDS_${PN} = "bash"
|
|
|
|
python do_package_prepend() {
|
|
d.setVar('PKGV', d.getVar("KERNEL_VERSION").split("-")[0])
|
|
}
|
|
|
|
B = "${WORKDIR}/${BPN}-${PV}"
|