mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-05-10 10:01:07 +00:00
7ed921f885
The previous patch 0001-Fix-macro-error.patch erroneously assumes that the 'MACRO1##MACRO2' operation expands the macros before concatination. As a result the UTEMPTER_DEFAULT_PATHNAME always gets the literal RAW_UTEMPTER_PATH value. Signed-off-by: iddinev <xidinev@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
43 lines
1.3 KiB
BlitzBasic
43 lines
1.3 KiB
BlitzBasic
SUMMARY = "A privileged helper for utmp/wtmp updates"
|
|
DESCRIPTION = "\
|
|
This library provides interface for terminal emulators such as \
|
|
screen and xterm to record user sessions to utmp and wtmp files."
|
|
HOMEPAGE = "ftp://ftp.altlinux.org/pub/people/ldv/utempter"
|
|
SECTION = "System Environment/Libraries"
|
|
LICENSE = "GPLv2 & GPLv2+ & LGPLv2 & MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"
|
|
|
|
SRCREV = "3ef74fff310f09e2601e241b9f042cd39d591018"
|
|
PV = "1.1.6-alt2+git${SRCPV}"
|
|
|
|
SRC_URI = "git://git.altlinux.org/people/ldv/packages/libutempter.git \
|
|
file://0001-Fix-macro-error.patch \
|
|
file://0002-Proper-macro-path-generation.patch \
|
|
file://libutempter-remove-glibc-assumption.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git/${BPN}"
|
|
|
|
CFLAGS += "-DLIBEXECDIR=${libexecdir}"
|
|
|
|
do_compile() {
|
|
oe_runmake \
|
|
libdir=${libdir} \
|
|
libexecdir=${libexecdir}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install \
|
|
DESTDIR=${D} \
|
|
libdir="${libdir}" \
|
|
libexecdir="${libexecdir}" \
|
|
includedir=${includedir} \
|
|
mandir=${mandir}
|
|
|
|
rm -f ${D}${libdir}/*.a
|
|
}
|
|
|
|
FILES_${PN} = "${libdir}/*.so.*"
|
|
FILES_${PN} += "${libexecdir}/utempter/utempter"
|
|
FILES_${PN}-dbg += "${libexecdir}/utempter/.debug/utempter"
|