mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
4fdeb484c2
The underscores and hyphens in the product name are used randomly in the CVE database: sqlite> select * from PRODUCTs where vendor = 'gnome' and product like '%keyr%'; CVE-2012-3466|gnome|gnome-keyring|3.4.0|=|| CVE-2012-3466|gnome|gnome-keyring|3.4.1|=|| CVE-2012-6111|gnome|gnome_keyring|3.2|=|| CVE-2012-6111|gnome|gnome_keyring|3.4|=|| CVE-2018-19358|gnome|gnome-keyring|||3.28.2|<= CVE-2018-20781|gnome|gnome_keyring|||3.27.2|< Set CVE_PRODUCT so that both versions are matched. Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
SUMMARY = "Password and keyring managing daemon"
|
|
HOMEPAGE = "http://www.gnome.org/"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
SECTION = "x11/gnome"
|
|
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.0-or-later & LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
|
|
"
|
|
|
|
CVE_PRODUCT = "gnome-keyring gnome_keyring"
|
|
|
|
DEPENDS = " \
|
|
glib-2.0-native \
|
|
gtk+3 \
|
|
gcr3 \
|
|
libgcrypt \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)} \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "autotools"
|
|
inherit gnomebase gsettings features_check gettext
|
|
|
|
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
|
|
|
|
SRC_URI[archive.sha256sum] = "bf26c966b8a8b7f3285ecc8bb3e467b9c20f9535b94dc451c9c559ddcff61925"
|
|
SRC_URI += " \
|
|
file://0001-Set-paths-to-ssh-agent-and-ssh-add-by-configure-opti.patch \
|
|
file://musl.patch \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "ssh-agent"
|
|
PACKAGECONFIG[ssh-agent] = "--enable-ssh-agent --with-ssh-agent-path=${bindir}/ssh-agent --with-ssh-add-path=${bindir}/ssh-add,--disable-ssh-agent,,openssh-misc"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-doc \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam --with-pam-dir=${base_libdir}/security', '--disable-pam', d)} \
|
|
"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1/services \
|
|
${datadir}/p11-kit \
|
|
${datadir}/xdg-desktop-portal \
|
|
${base_libdir}/security/*${SOLIBSDEV} \
|
|
${libdir}/pkcs11/gnome-keyring-pkcs11.so \
|
|
${systemd_user_unitdir} \
|
|
"
|
|
# fix | gnome-keyring-daemon: insufficient process capabilities, unsecure memory might get used
|
|
pkg_postinst:${PN} () {
|
|
setcap cap_ipc_lock+ep $D/${bindir}/gnome-keyring-daemon
|
|
}
|
|
PACKAGE_WRITE_DEPS += "libcap-native"
|