mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
59bff77ad0
This patch updates SRC_URIs using git to include branch=master if no branch is set and also to use protocol=https for github urls as generated by the conversion script in OE-Core. Signed-off-by: Armin Kuster <akuster808@gmail.com>
102 lines
4.3 KiB
BlitzBasic
102 lines
4.3 KiB
BlitzBasic
SUMMARY = "Music Player Daemon"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
HOMEPAGE ="http://www.musicpd.org"
|
|
|
|
inherit autotools useradd systemd pkgconfig
|
|
|
|
DEPENDS += " \
|
|
curl \
|
|
sqlite3 \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio', d)} \
|
|
yajl \
|
|
boost \
|
|
icu \
|
|
dbus \
|
|
expat \
|
|
"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/MusicPlayerDaemon/MPD;branch=v0.20.x;protocol=https \
|
|
file://mpd.conf.in \
|
|
file://0001-StringBuffer-Include-cstddef-for-size_t.patch \
|
|
file://0002-Include-stdexcept-for-runtime_error.patch \
|
|
"
|
|
SRCREV = "9274bc15bc41bbe490fde847f8422468cc20375d"
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
|
|
|
|
PACKAGECONFIG ??= "alsa ao bzip2 daemon ffmpeg fifo flac fluidsynth iso9660 jack libsamplerate libwrap httpd mms mpg123 modplug sndfile upnp openal opus oss recorder vorbis wavpack zlib"
|
|
PACKAGECONFIG += "${@bb.utils.contains('LICENSE_FLAGS', 'commercial', 'aac', '', d)}"
|
|
|
|
PACKAGECONFIG[aac] = "--enable-aac,--disable-aac,faad2"
|
|
PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib"
|
|
PACKAGECONFIG[ao] = "--enable-ao,--disable-ao,libao"
|
|
PACKAGECONFIG[audiofile] = "--enable-audiofile,--disable-audiofile,audiofile"
|
|
PACKAGECONFIG[bzip2] = "--enable-bzip2,--disable-bzip2,bzip2"
|
|
PACKAGECONFIG[cdioparanoia] = "--enable-cdio-paranoia,--disable-cdio-paranoia,libcdio-paranoia"
|
|
PACKAGECONFIG[daemon] = "--enable-daemon,--disable-daemon"
|
|
PACKAGECONFIG[ffmpeg] = "--enable-ffmpeg,--disable-ffmpeg,ffmpeg"
|
|
PACKAGECONFIG[fifo] = "--enable-fifo,--disable-fifo"
|
|
PACKAGECONFIG[flac] = "--enable-flac,--disable-flac,flac"
|
|
PACKAGECONFIG[fluidsynth] = "--enable-fluidsynth,--disable-fluidsynth,fluidsynth"
|
|
PACKAGECONFIG[httpd] = "--enable-httpd-output,--disable-httpd-output"
|
|
PACKAGECONFIG[id3tag] = "--enable-id3,--disable-id3,libid3tag"
|
|
PACKAGECONFIG[iso9660] = "--enable-iso9660,--disable-iso9660,libcdio"
|
|
PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack"
|
|
PACKAGECONFIG[lame] = "--enable-lame-encoder,--disable-lame-encoder,lame"
|
|
PACKAGECONFIG[libsamplerate] = "--enable-lsr,--disable-lsr,libsamplerate0"
|
|
PACKAGECONFIG[libwrap] = "--enable-libwrap,--disable-libwrap,tcp-wrappers"
|
|
PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
|
|
PACKAGECONFIG[mms] = "--enable-mms,--disable-mms,libmms"
|
|
PACKAGECONFIG[modplug] = "--enable-modplug,--disable-modplug,libmodplug"
|
|
PACKAGECONFIG[mpg123] = "--enable-mpg123,--disable-mpg123,mpg123"
|
|
PACKAGECONFIG[openal] = "--enable-openal,--disable-openal,openal-soft"
|
|
PACKAGECONFIG[opus] = "--enable-opus,--disable-opus,libopus libogg"
|
|
PACKAGECONFIG[oss] = "--enable-oss,--disable-oss,"
|
|
PACKAGECONFIG[recorder] = "--enable-recorder-output,--disable-recorder-output"
|
|
PACKAGECONFIG[smb] = "--enable-smbclient,--disable-smbclient,samba"
|
|
PACKAGECONFIG[sndfile] = "--enable-sndfile,--disable-sndfile,libsndfile1"
|
|
PACKAGECONFIG[upnp] = "--enable-upnp,--disable-upnp,libupnp"
|
|
PACKAGECONFIG[vorbis] = "--enable-vorbis,--disable-vorbis,libvorbis libogg"
|
|
PACKAGECONFIG[wavpack] = "--enable-wavpack,--disable-wavpack,wavpack"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib"
|
|
|
|
do_configure_prepend() {
|
|
sed -i -e 's|libsystemd-daemon|libsystemd|' ${S}/configure.ac
|
|
}
|
|
|
|
do_install_append() {
|
|
install -o mpd -d \
|
|
${D}/${localstatedir}/lib/mpd \
|
|
${D}/${localstatedir}/lib/mpd/playlists
|
|
install -m775 -o mpd -g mpd -d \
|
|
${D}/${localstatedir}/lib/mpd/music
|
|
|
|
install -d ${D}/${sysconfdir}
|
|
install -m 644 ${WORKDIR}/mpd.conf.in ${D}/${sysconfdir}/mpd.conf
|
|
sed -i \
|
|
-e 's|%music_directory%|${localstatedir}/lib/mpd/music|' \
|
|
-e 's|%playlist_directory%|${localstatedir}/lib/mpd/playlists|' \
|
|
-e 's|%db_file%|${localstatedir}/lib/mpd/mpd.db|' \
|
|
-e 's|%log_file%|${localstatedir}/log/mpd.log|' \
|
|
-e 's|%state_file%|${localstatedir}/lib/mpd/state|' \
|
|
${D}/${sysconfdir}/mpd.conf
|
|
|
|
# we don't need the icon
|
|
rm -rf ${D}${datadir}/icons
|
|
}
|
|
|
|
RPROVIDES_${PN} += "${PN}-systemd"
|
|
RREPLACES_${PN} += "${PN}-systemd"
|
|
RCONFLICTS_${PN} += "${PN}-systemd"
|
|
SYSTEMD_SERVICE_${PN} = "mpd.socket"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = " \
|
|
--system --no-create-home \
|
|
--home ${localstatedir}/lib/mpd \
|
|
--groups audio \
|
|
--user-group mpd"
|