mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-17 00:08:08 +00:00
5b4e26adb8
- The project uses CCFLAGS instead of CXXFLAGS to add C++ compiler flags. Assign the value of CXXFLAGS to the CCFLAGS variable and export CCFLAGS for use in the build environment. It fixes the contains reference TMPDIR because DEBUG_PREFIX_MAP is already included in CXXFLAGS (poky/meta/conf/bitbake.conf) - Fix typo -Wnodeprecated-declarations -> -Wno-deprecated-declarations ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE_Compression.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE_ETCL_Parser.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE_ETCL.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE_Monitor_Control.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: QA Issue: File /usr/lib/.debug/libACE_RLECompression.so.8.0.2 in package ace-dbg contains reference to TMPDIR [buildpaths] ERROR: ace-8.0.2-r0 do_package_qa: Fatal QA errors were found, failing task. Signed-off-by: Alper Ak <alperyasinak1@gmail.com> Suggested-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Khem Raj <raj.khem@gmail.com>
47 lines
1.4 KiB
BlitzBasic
47 lines
1.4 KiB
BlitzBasic
SUMMARY = "C++ framework for implementing distributed and networked applications"
|
|
DESCRIPTION = "C++ network programming framework that implements many core \
|
|
patterns for concurrent communication software"
|
|
LICENSE = "ACE-TAO-CIAO"
|
|
HOMEPAGE = "http://www.dre.vanderbilt.edu/~schmidt/ACE.html"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d2c090e9c730fd91677782d8e2091d77"
|
|
|
|
DEPENDS += "openssl gperf-native"
|
|
|
|
SRC_URI = "https://github.com/DOCGroup/ACE_TAO/releases/download/ACE%2BTAO-8_0_2/ACE-${PV}.tar.bz2 \
|
|
file://ace_config.patch \
|
|
file://no_sysctl.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "dba38a905858ec4a44c04b4bbaef42b891adf061e8c0bbdaa1dce2c04fcccb7f"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/DOCGroup/ACE_TAO/releases"
|
|
UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)"
|
|
|
|
CVE_STATUS[CVE-2009-1147] = "cpe-incorrect: this CVE is for vmware ace"
|
|
|
|
COMPATIBLE_HOST:libc-musl = "null"
|
|
|
|
S = "${UNPACKDIR}/ACE_wrappers"
|
|
B = "${UNPACKDIR}/ACE_wrappers/ace"
|
|
export ACE_ROOT = "${UNPACKDIR}/ACE_wrappers"
|
|
|
|
inherit pkgconfig
|
|
|
|
CXXFLAGS:append = " -fpermissive -Wno-deprecated-declarations"
|
|
CXX:append = " -ffile-prefix-map=${UNPACKDIR}= "
|
|
export CCFLAGS = "${CXXFLAGS}"
|
|
|
|
EXTRA_OEMAKE += "INSTALL_LIB=${baselib} install_rpath=0"
|
|
|
|
do_install() {
|
|
export D="${D}"
|
|
oe_runmake install
|
|
|
|
for i in $(find ${D} -name "*.pc") ; do
|
|
sed -i -e s:${D}::g \
|
|
-e s:/${TARGET_SYS}::g \
|
|
$i
|
|
done
|
|
|
|
rm -r ${D}/usr/share
|
|
}
|