mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-05-20 01:35:42 +00:00
60e962ace9
Changes in 5.4.2
NEW in "using" context, $# means "number of columns in current data line"
NEW define on program entry: I = sqrt(-1) = {0.,1.}
NEW support input data that uses epidemiological date-week formats
NEW optional fillcolor for "set key opaque"
NEW provide and document use of a plugin to provide uigamma function
CHANGE much improved domain and precision for igamma function
CHANGE generate only one key entry per multi-dataset input file Bug #2380
CHANGE (Windows): attempt to convert unicode on command line to UTF-8
CHANGE clip `with image` to plot boundary in 2D plots
CHANGE In gprintf format "%c", add no space for a null prefix Bug #2266
CHANGE Make auto-placement of left border less sensitive to plot size Bug #2415
FIX time formats %U %W Bug #2390
FIX left-justification of titles in splot with user-specified key position
FIX clipping of filled polygons that have only 1 or 2 vertices Bug #2400
FIX "set tics front" unexpectedly made all grid lines invisible
FIX more terminals support requested linewidth for textbox borders
FIX indexing of multiple matrix data sets in a single input file
FIX do not inject extra '\n' into input stream after 'set term' Bug #2292
FIX cairo terminals: Do not lose font info during multi-line enhanced text
FIX cairo terminals (Windows): ignore "text scaling" from user screen settings
FIX pm: better mousing and font handling
FIX win: instabilities associated with changing window size Bug #2301 #2304
FIX wxt: use of multiple plot windows from single-threaded wxt terminal
FIX qt: prevent creation of zombie gnuplot_qt process Bug #2188
Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
72 lines
2.5 KiB
BlitzBasic
72 lines
2.5 KiB
BlitzBasic
SUMMARY = "Gnuplot is a portable command-line driven graphing utility"
|
|
DESCRIPTION = "Gnuplot is a portable command-line driven interactive datafile \
|
|
(text or binary) and function plotting utility."
|
|
HOMEPAGE = "http://www.gnuplot.info/"
|
|
SECTION = "console/scientific"
|
|
LICENSE = "gnuplot"
|
|
LIC_FILES_CHKSUM = "file://Copyright;md5=243a186fc2fd3b992125d60d5b1bab8f"
|
|
DEPENDS = "${BPN}-native virtual/libx11 gd readline"
|
|
|
|
inherit autotools features_check
|
|
# depends on virtual/libx11
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
SRC_URI = " \
|
|
${SOURCEFORGE_MIRROR}/project/${BPN}/${BPN}/${PV}/${BP}.tar.gz;name=archive \
|
|
http://www.mneuroth.de/privat/zaurus/qtplot-0.2.tar.gz;name=qtplot \
|
|
file://gnuplot.desktop \
|
|
file://gnuplot.png \
|
|
"
|
|
SRC_URI:append:class-target = " \
|
|
file://0002-do-not-build-demos.patch \
|
|
file://0003-Use-native-tools-to-build-docs.patch \
|
|
file://0004-Add-configure-option-to-find-qt5-native-tools.patch \
|
|
"
|
|
|
|
SRC_URI[archive.sha256sum] = "e57c75e1318133951d32a83bcdc4aff17fed28722c4e71f2305cfc2ae1cae7ba"
|
|
SRC_URI[qtplot.sha256sum] = "6df317183ff62cc82f3dcf88207a267cd6478cb5147f55d7530c94f1ad5f4132"
|
|
|
|
# for building docs (they deserve it) we need *doc2* tools native
|
|
BBCLASSEXTEND = "native"
|
|
DEPENDS:class-native = "readline-native"
|
|
PACKAGECONFIG:class-native = ""
|
|
|
|
SRC_URI:append:class-native = " file://0001-reduce-build-to-conversion-tools-for-native-build.patch"
|
|
|
|
do_install:class-native() {
|
|
install -d ${D}${bindir}
|
|
install ${B}/docs/*doc* ${D}${bindir}
|
|
rm ${D}${bindir}/*.o
|
|
}
|
|
|
|
PACKAGECONFIG ??= "cairo"
|
|
PACKAGECONFIG[cairo] = "--with-cairo,--without-cairo,cairo pango"
|
|
PACKAGECONFIG[lua] = "--with-lua,--without-lua,lua"
|
|
PACKAGECONFIG[qt5] = "--with-qt --with-qt5nativesysroot=${STAGING_DIR_NATIVE},--without-qt,qtbase-native qtbase qtsvg qttools-native"
|
|
|
|
EXTRA_OECONF = " \
|
|
--with-readline=${STAGING_LIBDIR}/.. \
|
|
-disable-wxwidgets \
|
|
"
|
|
|
|
do_compile:prepend() {
|
|
install -m 0644 ${WORKDIR}/qtplot-0.2/qtopia.trm ${S}/term/
|
|
}
|
|
|
|
do_install:append:class-target() {
|
|
install -d ${D}${datadir}/applications/
|
|
install -m 0644 ${WORKDIR}/gnuplot.desktop ${D}${datadir}/applications/
|
|
install -d ${D}${datadir}/pixmaps/
|
|
install -m 0644 ${WORKDIR}/gnuplot.png ${D}${datadir}/pixmaps/
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-x11"
|
|
|
|
RPROVIDES:${PN}-dbg += "${PN}-x11-dbg"
|
|
|
|
DESCRIPTION:${PN}-x11 = "X11 display terminal for Gnuplot."
|
|
SECTION:${PN}-x11 = "x11/scientific"
|
|
FILES:${PN}-x11 = "${libexecdir} ${datadir}/applications ${datadir}/pixmaps ${libdir}/X11 "
|
|
|
|
FILES:${PN} += "${datadir}/texmf"
|