mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
8b29bc67af
* automake patch from 4.4.4 is no longer needed * PACKAGECONFIG for lua (lua term is only useful for LaTeX) * linking problems with dlopen, etc. in lua loadlibs.c fixed ** this same problem was seen in jansa world builds for 4.4.4 ** I am not able to replicate that error on 4.4.4 NOTE: qt is supported by this version, but I was not able to figure out the configuration... Signed-off-by: Tim Orling <TicoTimo@gmail.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
40 lines
1.3 KiB
PHP
40 lines
1.3 KiB
PHP
DESCRIPTION = "Gnuplot is a portable command-line driven interactive datafile \
|
|
(text or binary) and function plotting utility."
|
|
HOMEPAGE = "http://www.gnuplot.info/"
|
|
SECTION = "console/scientific"
|
|
LICENSE = "BSD-4"
|
|
LIC_FILES_CHKSUM = "file://Copyright;md5=243a186fc2fd3b992125d60d5b1bab8f"
|
|
DEPENDS = "virtual/libx11 gd readline"
|
|
|
|
inherit autotools
|
|
|
|
acpaths = ""
|
|
|
|
PACKAGECONFIG ??= "cairo"
|
|
PACKAGECONFIG[cairo] = "--with-cairo,--without-cairo,cairo pango"
|
|
PACKAGECONFIG[lua] = "--with-lua,--without-lua,lua"
|
|
|
|
EXTRA_OECONF = "--with-readline=${STAGING_LIBDIR}/.. \
|
|
--without-lisp-files \
|
|
--without-tutorial \
|
|
--disable-wxwidgets"
|
|
|
|
do_compile_prepend() {
|
|
install -m 0644 ${WORKDIR}/qtplot-0.2/qtopia.trm ${S}/term/
|
|
}
|
|
|
|
do_install_append() {
|
|
install -d ${D}${datadir}/applications/
|
|
install -m 0644 ${WORKDIR}/gnuplot.desktop ${D}${datadir}/applications/
|
|
install -d ${D}${datadir}/pixmaps/
|
|
install -m 0644 ${WORKDIR}/gnuplot.png ${D}${datadir}/pixmaps/
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-x11-dbg ${PN}-x11"
|
|
DESCRIPTION_${PN}-x11 = "X11 display terminal for Gnuplot."
|
|
SECTION_${PN}-x11 = "x11/scientific"
|
|
FILES_${PN}-x11 = "${libexecdir} ${datadir}/applications ${datadir}/pixmaps ${libdir}/X11 "
|
|
|
|
FILES_${PN} += "${datadir}/texmf"
|
|
FILES_${PN}-x11-dbg += "${libexecdir}/gnuplot/*/.debug"
|