mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
8bea89d3a9
Major changes in 1.60.0 ======================= * CVE-2026-28296: ftp: Reject paths with CR/LF in g_vfs_ftp_file_new_from_ftp (Ondrej Holy) * monitor: Do not load monitors when GIO_USE_VFS=local (Ondrej Holy) Major changes in 1.59.90 ======================== * client: Fix use-after-free when creating async proxy failed (Ondrej Holy) * udisks2: Emit changed signals from update_all() (Ondrej Holy) * daemon: Fix race on subscribers list when on thread (Ondrej Holy) * ftp: Validate fe_size when parsing symlink target (Ondrej Holy) * ftp: Check localtime() return value before use (Ondrej Holy) * CVE-2026-28295: ftp: Use control connection address for PASV data (Ondrej Holy) * CVE-2026-28296: ftp: Reject paths containing CR/LF characters (Ondrej Holy) * gphoto2: Use g_try_realloc() instead of g_realloc() (Ondrej Holy) * cdda: Reject path traversal in mount URI host (Ondrej Holy) * client: Fail when URI has invalid UTF-8 chars (Ondrej Holy) * udisks2: Fix memory corruption with duplicate mount paths (Alessandro Astone) * build: Update GOA dependency to > 3.57.0 (Jan-Michael Brummer) * Some other fixes (correctmost, Ondrej Holy) Major changes in 1.59.1 ======================= * mtp: replace Android extension checks with capability checks (Raul Tambre) * cdda: Fix duration of last track for some media (Bastien Nocera) * dav: Add X-OC-Mtime header on push to preserve last modified time (Lawrence Murray) * udisks2: Use hash tables in the volume monitor to improve performance (Milan Crha) * onedrive: Check for identity instead of presentation identity (Jan-Michael Brummer) * build: Disable google option and mark as deprecated (Jeremy Bícha, Ondrej Holy) * Fix various memory leaks (Milan Crha) * Some other fixes (wangrong, Jan-Michael Brummer, Simon Poirier) * Translation updates (GNOME Translation Project contributors) Major changes in 1.58.4 ======================= * Re-release of 1.58.3 due to incorrect release tag; no code changes. Major changes in 1.58.3 ======================= * CVE-2026-28296: ftp: Reject paths with CR/LF in g_vfs_ftp_file_new_from_ftp (Ondrej Holy) * monitor: Do not load monitors when GIO_USE_VFS=local (Ondrej Holy) Signed-off-by: Zhang Peng <peng.zhang1.cn@windriver.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
88 lines
3.4 KiB
BlitzBasic
88 lines
3.4 KiB
BlitzBasic
DESCRIPTION = "gvfs is a userspace virtual filesystem"
|
|
LICENSE = "LGPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=05df38dd77c35ec8431f212410a3329e"
|
|
|
|
inherit gnomebase gsettings bash-completion gettext upstream-version-is-even features_check
|
|
|
|
DEPENDS += "\
|
|
dbus \
|
|
glib-2.0 \
|
|
glib-2.0-native \
|
|
gsettings-desktop-schemas \
|
|
libgudev \
|
|
libsecret \
|
|
libxml2 \
|
|
shadow-native \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "gsettings-desktop-schemas"
|
|
|
|
SRC_URI = "https://download.gnome.org/sources/${BPN}/${@gnome_verdir("${PV}")}/${BPN}-${PV}.tar.xz;name=archive"
|
|
SRC_URI[archive.sha256sum] = "648273f069e92c7e3c013b92148e82c901f08044e2b3b14c6cfbd52269f6b646"
|
|
|
|
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
|
|
|
|
EXTRA_OEMESON = " \
|
|
-Dbluray=false \
|
|
"
|
|
|
|
PACKAGES =+ "gvfsd-ftp gvfsd-sftp gvfsd-trash"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/glib-2.0 \
|
|
${datadir}/GConf \
|
|
${datadir}/dbus-1/services \
|
|
${libdir}/gio/modules/*.so \
|
|
${libdir}/tmpfiles.d \
|
|
${systemd_user_unitdir} \
|
|
"
|
|
|
|
FILES:${PN}-dbg += "${libdir}/gio/modules/.debug/*"
|
|
FILES:${PN}-dev += "${libdir}/gio/modules/*.la"
|
|
|
|
FILES:gvfsd-ftp = "${libexecdir}/gvfsd-ftp ${datadir}/gvfs/mounts/ftp.mount"
|
|
FILES:gvfsd-sftp = "${libexecdir}/gvfsd-sftp ${datadir}/gvfs/mounts/sftp.mount"
|
|
FILES:gvfsd-trash = "${libexecdir}/gvfsd-trash ${datadir}/gvfs/mounts/trash.mount"
|
|
|
|
RRECOMMENDS:gvfsd-ftp += "openssh-sftp openssh-ssh"
|
|
|
|
PACKAGECONFIG ?= "libgphoto2 \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','polkit','udisks2','',d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','polkit','admin','',d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[udisks2] = "-Dudisks2=true, -Dudisks2=false, udisks2, udisks2"
|
|
PACKAGECONFIG[admin] = "-Dadmin=true, -Dadmin=false, libcap polkit"
|
|
PACKAGECONFIG[afc] = "-Dafc=true, -Dafc=false, libimobiledevice libplist"
|
|
PACKAGECONFIG[archive] = "-Darchive=true, -Darchive=false, libarchive"
|
|
PACKAGECONFIG[dnssd] = "-Ddnssd=true, -Ddnssd=false, avahi"
|
|
PACKAGECONFIG[gcr] = "-Dgcr=true, -Dgcr=false, gcr"
|
|
PACKAGECONFIG[gcrypt] = "-Dgcrypt=true, -Dgcrypt=false, libgcrypt"
|
|
PACKAGECONFIG[goa] = "-Dgoa=true, -Dgoa=false, gnome-online-accounts"
|
|
PACKAGECONFIG[google] = "-Dgoogle=true, -Dgoogle=false, libgdata"
|
|
PACKAGECONFIG[http] = "-Dhttp=true, -Dhttp=false, libsoup-3.0"
|
|
PACKAGECONFIG[libmtp] = "-Dmtp=true, -Dmtp=false, libmtp"
|
|
PACKAGECONFIG[logind] = "-Dlogind=true, -Dlogind=false, systemd"
|
|
PACKAGECONFIG[libgphoto2] = "-Dgphoto2=true, -Dgphoto2=false, libgphoto2"
|
|
PACKAGECONFIG[nfs] = "-Dnfs=true, -Dnfs=false,libnfs"
|
|
PACKAGECONFIG[onedrive] = "-Donedrive=true, -Donedrive=false, msgraph"
|
|
PACKAGECONFIG[samba] = "-Dsmb=true, -Dsmb=false, samba"
|
|
PACKAGECONFIG[systemd] = "-Dsystemduserunitdir=${systemd_user_unitdir} -Dtmpfilesdir=${libdir}/tmpfiles.d, -Dsystemduserunitdir=no -Dtmpfilesdir=no, systemd"
|
|
|
|
# needs meta-filesystems
|
|
PACKAGECONFIG[fuse] = "-Dfuse=true, -Dfuse=false, fuse3"
|
|
|
|
# libcdio-paranoia recipe doesn't exist yet
|
|
PACKAGECONFIG[cdda] = "-Dcdda=true, -Dcdda=false, libcdio-paranoia"
|
|
|
|
do_install:append() {
|
|
# After rebuilds (not from scracth) it can happen that the executables in
|
|
# libexec ar missing executable permission flag. Not sure but it came up
|
|
# during transition to meson. Looked into build files and logs but could
|
|
# not find suspicious
|
|
for exe in `find ${D}/${libexecdir}`; do
|
|
chmod +x $exe
|
|
done
|
|
}
|