mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-07 06:28:49 +00:00
2cd4763dc1
In order to facilitate users who wish to use e.g. dbus-broker as their
runtime D-Bus implementation, change the Freedesktop.org specific D-Bus
runtime dependency to honor oe-core's new VIRTUAL-RUNTIME_dbus
variable.
With this change we also align with oe-core commit 5dfca64b78
("dbus-glib: depend on dbus, not dbus-x11") which mentions that
dbus-x11 hasn't existed as a package since 2012[1] and is just a
RPROVIDES in dbus, so depend on dbus directly instead.
Signed-off-by: Niko Mauno <niko.mauno@vaisala.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
51 lines
1.7 KiB
BlitzBasic
51 lines
1.7 KiB
BlitzBasic
DESCRIPTION = "a graphical user interface that allows the user to change print settings"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "git://github.com/OpenPrinting/system-config-printer.git;protocol=https;branch=master"
|
|
|
|
SRCREV = "895d3dec50c93bfd4f142bac9bfcc13051bf84cb"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools gettext pkgconfig python3native features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
|
|
|
|
DEPENDS = "cups glib-2.0 libusb xmlto-native desktop-file-utils-native autoconf-archive-native python3-setuptools-native"
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd polkit', d)}"
|
|
PACKAGECONFIG[systemd] = ",--without-systemdsystemunitdir,systemd"
|
|
PACKAGECONFIG[polkit] = ",,,cups-pk-helper"
|
|
|
|
do_configure:prepend() {
|
|
# This file is not provided if fetching from git but required for configure
|
|
touch ${S}/ChangeLog
|
|
}
|
|
|
|
do_install:append() {
|
|
cp -rf ${B}/cupshelpers.egg-info ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
cp -rf ${B}/cupshelpers ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
rm -rf ${D}${PYTHON_SITEPACKAGES_DIR}/*.egg
|
|
for f in __init__.cpython-311.pyc cupshelpers.cpython-311.pyc \
|
|
config.cpython-311.pyc ppds.cpython-311.pyc \
|
|
installdriver.cpython-311.pyc openprinting.cpython-311.pyc \
|
|
xmldriverprefs.cpython-311.pyc; do
|
|
rm -rf ${D}${PYTHON_SITEPACKAGES_DIR}/cupshelpers/__pycache__/$f
|
|
done
|
|
}
|
|
|
|
FILES:${PN} += "${libdir} ${datadir}"
|
|
|
|
RDEPENDS:${PN} = " \
|
|
cups \
|
|
${VIRTUAL-RUNTIME_dbus} \
|
|
gtk+3 \
|
|
libnotify \
|
|
python3-core \
|
|
python3-dbus \
|
|
python3-firewall \
|
|
python3-pycups \
|
|
python3-pycurl \
|
|
python3-pygobject \
|
|
"
|