mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
9e4e5951fa
https://goodies.xfce.org/ states "Starting this month (November 2019), a project is starting to migrate the goodies.xfce.org documentation to https://docs.xfce.org/start. The goal is to remove deprecated projects and, eventually, de-commission the goodies.xfce.org URLs. Additional information will be posted on https://wiki.xfce.org/projects/goodies-decomm/start as the project proceeds." This patch updates the URLs being used in the HOMEPAGEs to reflect where the address is actually resolving. Signed-off-by: Jason Schonberg <schonm@gmail.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
46 lines
1.5 KiB
BlitzBasic
46 lines
1.5 KiB
BlitzBasic
SUMMARY = "Power manager for the Xfce desktop environment"
|
|
HOMEPAGE = "https://docs.xfce.org/xfce/xfce4-power-manager/start"
|
|
SECTION = "x11"
|
|
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
inherit xfce features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
DEPENDS += "libnotify libxrandr virtual/libx11 libxext xfce4-panel upower libxscrnsaver"
|
|
|
|
SRC_URI[sha256sum] = "971391cef63352833bdd92df28957392e17e1f2b3d486c0f57294fd204d6ed29"
|
|
|
|
EXTRA_OECONF = " \
|
|
GDBUS_CODEGEN=${STAGING_BINDIR_NATIVE}/gdbus-codegen \
|
|
--enable-panel-plugins \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'polkit', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'wayland', d)} \
|
|
"
|
|
PACKAGECONFIG[polkit] = "--enable-polkit, --disable-polkit, polkit"
|
|
PACKAGECONFIG[wayland] = "--enable-wayland, --disable-wayland, wayland-native"
|
|
|
|
PACKAGES += "xfce4-powermanager-plugin"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/metainfo \
|
|
"
|
|
|
|
FILES:xfce4-powermanager-plugin = " \
|
|
${libdir}/xfce4 \
|
|
${datadir}/xfce4 \
|
|
"
|
|
|
|
RDEPENDS:xfce4-powermanager-plugin = "${PN}"
|
|
RDEPENDS:${PN} = "networkmanager ${@bb.utils.contains('DISTRO_FEATURES','systemd','','consolekit',d)}"
|
|
|
|
# xfce4-brightness-plugin was replaced by xfce4-powermanager-plugin
|
|
RPROVIDES:xfce4-powermanager-plugin += "xfce4-brightness-plugin"
|
|
RREPLACES:xfce4-powermanager-plugin += "xfce4-brightness-plugin"
|
|
RCONFLICTS:xfce4-powermanager-plugin += "xfce4-brightness-plugin"
|