mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
b1ea104d04
libsdl3-mixer has initially released - binaries in wavpack-bin are only needed at runtime but cmake checks for them during compilation and fails because they are (presumably intentionally) not present in the target sysroot. Workround this issue by touching the necessary files to please cmake. Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
29 lines
1.6 KiB
BlitzBasic
29 lines
1.6 KiB
BlitzBasic
SUMMARY = "Provides decoding of many popular audio file formats, mixing, various DSP processing effects and positional audio"
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=df8f4d887d3997f6e9cf81bb7f43dbf7"
|
|
|
|
DEPENDS = "libsdl3"
|
|
|
|
SRC_URI = "git://github.com/libsdl-org/SDL_mixer.git;protocol=https;branch=release-3.2.x"
|
|
SRCREV = "cedfeef30e93db35eee6b25759117da63f8e5a4f"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
PACKAGECONFIG ?= "flac opus wave vorbis"
|
|
PACKAGECONFIG[opus] = "-DSDLMIXER_OPUS=ON -DSDLMIXER_OPUS_SHARED=ON, -DSDLMIXER_OPUS=OFF,opusfile"
|
|
PACKAGECONFIG[vorbis] = "-DSDLMIXER_VORBIS_VORBISFILE=ON -DSDLMIXER_VORBIS_STB=OFF -DSDLMIXER_VORBIS_TREMOR=OFF, -DSDLMIXER_VORBIS_VORBISFILE=OFF -DSDLMIXER_VORBIS_STB=OFF -DSDLMIXER_VORBIS_TREMOR=OFF,libvorbis"
|
|
PACKAGECONFIG[flac] = "-DSDLMIXER_FLAC_LIBFLAC=ON -DSDLMIXER_FLAC_LIBFLAC_SHARED=ON, -DSDLMIXER_FLAC_LIBFLAC=OFF,flac"
|
|
PACKAGECONFIG[xmp] = "-DSDLMIXER_MOD=ON -DSDLMIXER_MOD_XMP=ON -DSDLMIXER_MOD_XMP_SHARED=ON, -DSDLMIXER_MOD=OFF,libxmp,libxmp"
|
|
PACKAGECONFIG[fluidsynth] = "-DSDLMIXER_MIDI=ON -DSDLMIXER_MIDI_FLUIDSYNTH_ENABLED=ON -DSDLMIXER_MIDI_FLUIDSYNTH_SHARED=ON, -DSDLMIXER_MIDI=OFF,fluidsynth,fluidsynth-bin"
|
|
PACKAGECONFIG[wave] = "-DSDLMIXER_WAVE=ON -DSDLMIXER_WAVPACK=ON -DSDLMIXER_WAVPACK_SHARED=ON, -DSDLMIXER_WAVE=OFF,wavpack,wavpack wavpack-bin"
|
|
PACKAGECONFIG[mpg123] = "-DSDLMIXER_MP3 -DSDLMIXER_MP3_MPG123_SHARED=ON -DSDLMIXER_MP3_MPG123=ON, -DSDLMIXER_MP3=OFF,mpg123"
|
|
|
|
do_configure:prepend() {
|
|
touch ${STAGING_BINDIR}/wavpack
|
|
touch ${STAGING_BINDIR}/wvunpack
|
|
touch ${STAGING_BINDIR}/wvgain
|
|
touch ${STAGING_BINDIR}/wvtag
|
|
}
|
|
|
|
FILES:${PN} += "${datadir}/licenses"
|