mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
b2dc5ff70b
Upgrade urgency: SECURITY, contains fixes to security issues. Security Fixes: * (CVE-2023-28425) Specially crafted MSETNX command can lead to assertion and denial-of-service Bug Fixes ========= * Large blocks of replica client output buffer may lead to psync loops and unnecessary memory usage (#11666) * Fix CLIENT REPLY OFF|SKIP to not silence push notifications (#11875) * Trim excessive memory usage in stream nodes when exceeding `stream-node-max-bytes` (#11885) * Fix module RM_Call commands failing with OOM when maxmemory is changed to zero (#11319) Signed-off-by: Changqing Li <changqing.li@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> (cherry picked from commit b589edf930977dbd75418e05d618a8047982dd59) Signed-off-by: Armin Kuster <akuster808@gmail.com>
73 lines
2.6 KiB
BlitzBasic
73 lines
2.6 KiB
BlitzBasic
SUMMARY = "Redis key-value store"
|
|
DESCRIPTION = "Redis is an open source, advanced key-value store."
|
|
HOMEPAGE = "http://redis.io"
|
|
SECTION = "libs"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=8ffdd6c926faaece928cf9d9640132d2"
|
|
DEPENDS = "readline lua ncurses"
|
|
|
|
FILESPATH =. "${FILE_DIRNAME}/${BPN}-7:"
|
|
|
|
SRC_URI = "http://download.redis.io/releases/${BP}.tar.gz \
|
|
file://redis.conf \
|
|
file://init-redis-server \
|
|
file://redis.service \
|
|
file://hiredis-use-default-CC-if-it-is-set.patch \
|
|
file://lua-update-Makefile-to-use-environment-build-setting.patch \
|
|
file://oe-use-libc-malloc.patch \
|
|
file://0001-src-Do-not-reset-FINAL_LIBS.patch \
|
|
file://GNU_SOURCE-7.patch \
|
|
file://0006-Define-correct-gregs-for-RISCV32.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "1dee4c6487341cae7bd6432ff7590906522215a061fdef87c7d040a0cb600131"
|
|
|
|
inherit autotools-brokensep update-rc.d systemd useradd
|
|
|
|
FINAL_LIBS:x86:toolchain-clang = "-latomic"
|
|
FINAL_LIBS:riscv32:toolchain-clang = "-latomic"
|
|
FINAL_LIBS:mips = "-latomic"
|
|
FINAL_LIBS:arm = "-latomic"
|
|
FINAL_LIBS:powerpc = "-latomic"
|
|
|
|
export FINAL_LIBS
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --home-dir /var/lib/redis -g redis --shell /bin/false redis"
|
|
GROUPADD_PARAM:${PN} = "--system redis"
|
|
|
|
PACKAGECONFIG = "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[systemd] = "USE_SYSTEMD=yes,USE_SYSTEMD=no,systemd"
|
|
|
|
EXTRA_OEMAKE += "${PACKAGECONFIG_CONFARGS}"
|
|
|
|
do_compile:prepend() {
|
|
(cd deps && oe_runmake hiredis lua linenoise)
|
|
}
|
|
|
|
do_install() {
|
|
export PREFIX=${D}/${prefix}
|
|
oe_runmake install
|
|
install -d ${D}/${sysconfdir}/redis
|
|
install -m 0644 ${WORKDIR}/redis.conf ${D}/${sysconfdir}/redis/redis.conf
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 0755 ${WORKDIR}/init-redis-server ${D}/${sysconfdir}/init.d/redis-server
|
|
install -d ${D}/var/lib/redis/
|
|
chown redis.redis ${D}/var/lib/redis/
|
|
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${WORKDIR}/redis.service ${D}${systemd_system_unitdir}
|
|
sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${systemd_system_unitdir}/redis.service
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
sed -i 's!daemonize yes!# daemonize yes!' ${D}/${sysconfdir}/redis/redis.conf
|
|
sed -i 's!supervised no!supervised systemd!' ${D}/${sysconfdir}/redis/redis.conf
|
|
fi
|
|
}
|
|
|
|
CONFFILES:${PN} = "${sysconfdir}/redis/redis.conf"
|
|
|
|
INITSCRIPT_NAME = "redis-server"
|
|
INITSCRIPT_PARAMS = "defaults 87"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "redis.service"
|