mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-09-02 21:49:43 +00:00
8a54026a23
According to the COPYING file in the top level of the hostapd source tree, hostapd was re-licensed from dual BSD/GPLv2 to BSD only in February 2012. This change has apparently gone unnoticed for the past 6 years, but fix it now. Also use pkg-config to find libnl headers (instead of hardcoding), append to base do_configure (instead of over-riding), respect OE's default CFLAGS (instead of ignoring) and make some minor formatting tweaks to bring the recipe more in line with the OE Styleguide. Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
53 lines
1.6 KiB
BlitzBasic
53 lines
1.6 KiB
BlitzBasic
SUMMARY = "User space daemon for extended IEEE 802.11 management"
|
|
HOMEPAGE = "http://w1.fi/hostapd/"
|
|
SECTION = "kernel/userland"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://hostapd/README;md5=8aa4e8c78b59b12016c4cb2d0a8db350"
|
|
|
|
DEPENDS = "libnl openssl"
|
|
|
|
SRC_URI = " \
|
|
http://w1.fi/releases/hostapd-${PV}.tar.gz \
|
|
file://defconfig \
|
|
file://init \
|
|
file://hostapd.service \
|
|
file://key-replay-cve-multiple.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "eaa56dce9bd8f1d195eb62596eab34c7"
|
|
SRC_URI[sha256sum] = "01526b90c1d23bec4b0f052039cc4456c2fd19347b4d830d1d58a0a6aea7117d"
|
|
|
|
S = "${WORKDIR}/hostapd-${PV}"
|
|
B = "${WORKDIR}/hostapd-${PV}/hostapd"
|
|
|
|
inherit update-rc.d systemd pkgconfig distro_features_check
|
|
|
|
CONFLICT_DISTRO_FEATURES = "openssl-no-weak-ciphers"
|
|
|
|
INITSCRIPT_NAME = "hostapd"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "hostapd.service"
|
|
SYSTEMD_AUTO_ENABLE_${PN} = "disable"
|
|
|
|
do_configure_append() {
|
|
install -m 0644 ${WORKDIR}/defconfig ${B}/.config
|
|
}
|
|
|
|
do_compile() {
|
|
export CFLAGS="-MMD -O2 -Wall -g"
|
|
export EXTRA_CFLAGS="${CFLAGS}"
|
|
make V=1
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${B}/hostapd.conf ${D}${sysconfdir}
|
|
install -m 0755 ${B}/hostapd ${D}${sbindir}
|
|
install -m 0755 ${B}/hostapd_cli ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
|
|
install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service
|
|
}
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/hostapd.conf"
|