mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
be6b26e92c
This is a bugfix release. Changes: - USB HID dissector memory exhaustion. CVE-2026-3201. - NTS-KE dissector crash. CVE-2026-3202. - RF4CE Profile dissector crash. CVE-2026-3203. - Wireshark doesn’t start if Npcap is configured with "Restrict Npcap driver’s Access to Administrators only" - PQC signature algorithm not reported in signature_algorithms. - Unexpected JA4 ALPN values when space characters sent. - Expert Info seems to have quadratic performance (gets slower and slower) - IKEv2 EMERGENCY_CALL_NUMBERS Notify payload cannot be decoded. - TShark and editcap fails with segmentation fault when output format (-F) set to blf. - Fuzz job crash: fuzz-2026-02-01-12944805400.pcap [Zigbee Direct Tunneling Zigbee NWK PDUs NULL hash table] - Wiretap writes pcapng custom options with string values invalidly. - RDM status in Output Status (GoodOutputB) field incorrectly decoded in Art-Net PollReply dissector. - Wiretap writes invalid pcapng Darwin option blocks. - TDS dissector desynchronizes on RPC DATENTYPE (0x28) due to incorrect expectation of TYPE_VARLEN (MaxLen) - Only first HTTP POST is parsed inside SOCKS with "Decode As". - TShark: Bogus "Dissector bug" messages generated in pipelines where something after tshark exits before reading all its input. - New Diameter RAT-Types in TS 29.212 not decoded. - Malformed packet error on Trigger HE Basic frames. Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
106 lines
4.1 KiB
BlitzBasic
106 lines
4.1 KiB
BlitzBasic
DESCRIPTION = "wireshark - a popular network protocol analyzer"
|
|
HOMEPAGE = "http://www.wireshark.org"
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=570a9b3749dd0463a1778803b12a6dce"
|
|
|
|
DEPENDS = "pcre2 expat glib-2.0 glib-2.0-native libgcrypt libgpg-error libxml2 bison-native c-ares speexdsp virtual/libiconv"
|
|
|
|
DEPENDS:append:class-target = " wireshark-native chrpath-replacement-native "
|
|
|
|
SRC_URI = "https://1.eu.dl.wireshark.org/src/all-versions/wireshark-${PV}.tar.xz \
|
|
file://0001-wireshark-src-improve-reproducibility.patch \
|
|
file://0002-flex-Remove-line-directives.patch \
|
|
file://0004-lemon-Remove-line-directives.patch \
|
|
file://0001-UseLemon.cmake-do-not-use-lemon-data-from-the-host.patch \
|
|
"
|
|
|
|
SRC_URI:append:class-native = " file://0001-don-t-look-for-iconv.h-for-native-build.patch"
|
|
|
|
UPSTREAM_CHECK_URI = "https://1.as.dl.wireshark.org/src/all-versions"
|
|
|
|
SRC_URI[sha256sum] = "fbeab3d85c6c8a5763c8d9b7fe20b5c69ca9f9e7f2b824bedc73135bdca332e2"
|
|
|
|
PE = "1"
|
|
|
|
inherit cmake pkgconfig python3native python3targetconfig perlnative upstream-version-is-even mime mime-xdg
|
|
|
|
PACKAGECONFIG ?= "libpcap gnutls libnl libcap sbc"
|
|
|
|
PACKAGECONFIG:class-native = "libpcap gnutls ssl libssh"
|
|
|
|
PACKAGECONFIG[libcap] = "-DENABLE_CAP=ON,-DENABLE_CAP=OFF -DENABLE_PCAP_NG_DEFAULT=ON, libcap"
|
|
PACKAGECONFIG[libpcap] = "-DENABLE_PCAP=ON,-DENABLE_PCAP=OFF -DENABLE_PCAP_NG_DEFAULT=ON , libpcap"
|
|
PACKAGECONFIG[libsmi] = "-DENABLE_SMI=ON,-DENABLE_SMI=OFF,libsmi"
|
|
PACKAGECONFIG[libnl] = ",,libnl"
|
|
PACKAGECONFIG[portaudio] = "-DENABLE_PORTAUDIO=ON,-DENABLE_PORTAUDIO=OFF, portaudio-v19"
|
|
PACKAGECONFIG[gnutls] = "-DENABLE_GNUTLS=ON,-DENABLE_GNUTLS=OFF, gnutls"
|
|
PACKAGECONFIG[ssl] = ",,openssl"
|
|
PACKAGECONFIG[krb5] = "-DENABLE_KRB5=ON,-DENABLE_KRB5=OFF, krb5"
|
|
PACKAGECONFIG[lua] = "-DENABLE_LUA=ON,-DENABLE_LUA=OFF, lua"
|
|
PACKAGECONFIG[zlib] = "-DENABLE_ZLIB=ON,-DENABLE_ZLIB=OFF, zlib"
|
|
PACKAGECONFIG[geoip] = ",, geoip"
|
|
PACKAGECONFIG[plugins] = "-DENABLE_PLUGINS=ON,-DENABLE_PLUGINS=OFF"
|
|
PACKAGECONFIG[sbc] = "-DENABLE_SBC=ON,-DENABLE_SBC=OFF, sbc"
|
|
PACKAGECONFIG[libssh] = "-DENABLE_LIBSSH=ON,-DENABLE_LIBSSH=OFF, libssh2"
|
|
PACKAGECONFIG[lz4] = "-DENABLE_LZ4=ON,-DENABLE_LZ4=OFF, lz4"
|
|
PACKAGECONFIG[zstd] = "-DENABLE_ZSTD=ON,-DENABLE_ZSTD=OFF, zstd"
|
|
PACKAGECONFIG[nghttp2] = "-DENABLE_NGHTTP2=ON,-DENABLE_NGHTTP2=OFF, nghttp2"
|
|
|
|
# these next two options require addional layers
|
|
PACKAGECONFIG[qt5] = "-DENABLE_QT5=ON -DBUILD_wireshark=ON -DUSE_qt6=OFF, -DENABLE_QT5=OFF -DBUILD_wireshark=OFF, qttools-native qtmultimedia qtsvg"
|
|
|
|
inherit_defer ${@bb.utils.contains('PACKAGECONFIG', 'qt5', 'cmake_qt5', '', d)}
|
|
|
|
EXTRA_OECMAKE += "-DENABLE_NETLINK=ON \
|
|
-DBUILD_mmdbresolve=OFF \
|
|
-DBUILD_randpktdump=OFF \
|
|
-DBUILD_androiddump=OFF \
|
|
-DBUILD_dcerpcidl2wrs=OFF \
|
|
-DM_INCLUDE_DIR=${includedir} \
|
|
-DM_LIBRARY=${libdir} \
|
|
"
|
|
|
|
# use lemon from ${PN}-native, instead of cross-compiled or host versions
|
|
EXTRA_OECMAKE:append:class-target = " -DLEMON_EXECUTABLE=${STAGING_BINDIR_NATIVE}/lemon"
|
|
CFLAGS:append = " -lm"
|
|
|
|
do_compile:append:class-target() {
|
|
# Fix TMPDIR, these are in the comments section
|
|
sed -i -e "s:** source file.*::g" ${B}/wiretap/ascend_parser.c
|
|
sed -i -e "s:** source file.*::g" ${B}/wiretap/busmaster_parser.c
|
|
sed -i -e "s:** source file.*::g" ${B}/epan/protobuf_lang_parser.c
|
|
sed -i -e "s:** source file.*::g" ${B}/epan/dfilter/grammar.c
|
|
if [ -f "${B}/plugins/epan/mate/mate_grammar.c" ]; then
|
|
sed -i -e 's:** source file.*::g' "${B}/plugins/epan/mate/mate_grammar.c"
|
|
fi
|
|
}
|
|
|
|
do_install:append:class-native() {
|
|
install -d ${D}${bindir}
|
|
for f in lemon
|
|
do
|
|
install -m 0755 ${B}/run/$f ${D}${bindir}
|
|
done
|
|
}
|
|
|
|
do_install:append:class-target() {
|
|
for f in `find ${D}${libdir} ${D}${bindir} -type f -executable`
|
|
do
|
|
chrpath --delete $f
|
|
done
|
|
|
|
# We don't need the cmake files installed
|
|
rm -fr ${D}${usrlib}/${BPN}/cmake
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN += "tshark"
|
|
|
|
FILES:tshark = "${bindir}/tshark ${mandir}/man1/tshark.*"
|
|
|
|
FILES:${PN} += "${datadir}*"
|
|
|
|
RDEPENDS:tshark = "wireshark"
|
|
|
|
BBCLASSEXTEND = "native"
|