mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-04-02 02:49:12 +00:00
ede40e0d90
As the subject says. Fixes compilation error: | ../../../sources/minicoredumper-2.0.7/src/coreinject/main.c: In function 'inject_data': | ../../../sources/minicoredumper-2.0.7/src/coreinject/main.c:248:11: error: assignment discards 'const' qualifier from pointer target type [-Werror=discarded-qualifiers] | 248 | p = strrchr(b_fname, '/'); Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
52 lines
2.2 KiB
BlitzBasic
52 lines
2.2 KiB
BlitzBasic
SUMMARY = "minicoredumper provides an alternate core dump facility for Linux \
|
|
to allow minimal and customized crash dumps"
|
|
HOMEPAGE = "https://www.linutronix.de/minicoredumper/"
|
|
LICENSE = " LGPL-2.1-only & BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=71827c617ec7b45a0dd23658347cc1e9 \
|
|
file://COPYING.BSD;md5=b915ac80d5236d6aa659cb986daf00e5 \
|
|
file://COPYING.LGPLv2.1;md5=321bf41f280cf805086dd5a720b37785 \
|
|
"
|
|
DEPENDS = "elfutils dbus dbus-glib-native glib-2.0 dbus-glib util-linux json-c"
|
|
|
|
inherit autotools pkgconfig ptest systemd update-rc.d
|
|
|
|
SRCREV = "ca6e7ad62b4cf984de84aa081024c4e45632cecb"
|
|
|
|
SRC_URI = "git://github.com/diamon/minicoredumper;protocol=https;branch=master \
|
|
file://minicoredumper.service \
|
|
file://minicoredumper.init \
|
|
file://run-ptest \
|
|
file://0001-corestripper-Fix-uninitialized-warning.patch \
|
|
file://0002-Fix-2038-year-problem-in-timestamp-handling.patch \
|
|
file://0001-coreinject-fix-assignment-of-const-qualified-type.patch \
|
|
"
|
|
|
|
|
|
SYSTEMD_SERVICE:${PN} = "minicoredumper.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME:${PN} = "minicoredumper"
|
|
INITSCRIPT_PARAMS:${PN} = "defaults 89"
|
|
|
|
EXTRA_OECONF:append = " \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', '--with-minicoredumper_demo', '--without-libminicoredumper', d)} \
|
|
"
|
|
do_install:append() {
|
|
rmdir ${D}${localstatedir}/run
|
|
install -d ${D}/${sysconfdir}/minicoredumper
|
|
cp -rf ${S}/etc/* ${D}/${sysconfdir}/
|
|
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${UNPACKDIR}/minicoredumper.service ${D}${systemd_system_unitdir}
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 0755 ${UNPACKDIR}/minicoredumper.init ${D}${sysconfdir}/init.d/minicoredumper
|
|
|
|
# correct path of minicoredumper
|
|
sed -i -e s:/usr/bin/minicoredumper:${sbindir}/minicoredumper:g ${D}${sysconfdir}/init.d/minicoredumper
|
|
sed -i -e s:/usr/bin/minicoredumper:${sbindir}/minicoredumper:g ${D}${systemd_system_unitdir}/minicoredumper.service
|
|
}
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/186966/
|
|
COMPATIBLE_HOST:libc-musl = 'null'
|