mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-05-18 03:39:34 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
41 lines
1.5 KiB
BlitzBasic
41 lines
1.5 KiB
BlitzBasic
SUMMARY = "Web-based MySQL administration interface"
|
|
HOMEPAGE = "http://www.phpmyadmin.net"
|
|
# Main code is GPLv2, vendor/tecnickcom/tcpdf is under LGPLv3, js/jquery is under MIT
|
|
LICENSE = "GPL-2.0-only & LGPL-3.0-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://vendor/tecnickcom/tcpdf/LICENSE.TXT;md5=72bda492a00ee8c4121987c6afdefc07 \
|
|
file://js/vendor/jquery/MIT-LICENSE.txt;md5=de877aa6d744cc160ff41c26a8e4811f \
|
|
"
|
|
|
|
SRC_URI = "https://files.phpmyadmin.net/phpMyAdmin/${PV}/phpMyAdmin-${PV}-all-languages.tar.xz \
|
|
file://apache.conf \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f881819a3b11e653b0212afaf0cc105db85c767715cb3f5852670f7fc36c9669"
|
|
|
|
UPSTREAM_CHECK_URI = "https://www.phpmyadmin.net/downloads/"
|
|
UPSTREAM_CHECK_REGEX = "phpMyAdmin-(?P<pver>\d+(\.\d+)+)-all-languages.tar.xz"
|
|
|
|
S = "${UNPACKDIR}/phpMyAdmin-${PV}-all-languages"
|
|
|
|
inherit allarch
|
|
|
|
do_install() {
|
|
install -d ${D}${datadir}/${BPN}
|
|
cp -R --no-dereference --preserve=mode,links -v * ${D}${datadir}/${BPN}
|
|
chown -R root:root ${D}${datadir}/${BPN}
|
|
# Don't install patches to target
|
|
rm -rf ${D}${datadir}/${BPN}/patches
|
|
|
|
install -d ${D}${sysconfdir}/apache2/conf.d
|
|
install -m 0644 ${UNPACKDIR}/apache.conf ${D}${sysconfdir}/apache2/conf.d/phpmyadmin.conf
|
|
|
|
# Remove a few scripts that explicitly require bash (!)
|
|
rm -f ${D}${datadir}/phpmyadmin/libraries/transformations/*.sh
|
|
}
|
|
|
|
FILES:${PN} = "${datadir}/${BPN} \
|
|
${sysconfdir}/apache2/conf.d"
|
|
|
|
RDEPENDS:${PN} += "bash php-cli"
|