mirror of
git://git.openembedded.org/meta-openembedded
synced 2026-06-09 23:32:15 +00:00
fa4ceb7b5d
Details: https://nvd.nist.gov/vuln/detail/CVE-2024-36600 Backport the patch from the PR that is referenced in the NVD advisory. Note that there are two PRs mentioned: one is the fix, and the other is just readme update with the CVE ID. The latter wasn't backported. Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com> Signed-off-by: Anuj Mittal <anuj.mittal@oss.qualcomm.com>
34 lines
1.2 KiB
BlitzBasic
34 lines
1.2 KiB
BlitzBasic
SUMMARY = "The GNU Compact Disc Input and Control library (libcdio) contains a library for CD-ROM and CD image access."
|
|
HOMEPAGE = "http://www.gnu.org/software/libcdio/"
|
|
SECTION = "libs"
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/${PV}/${BP}.tar.bz2 \
|
|
file://CVE-2024-36600.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "6f8fbdf4d189cf63f2a7a1549c516cd720c7b222c7aaadbc924a26e745a48539"
|
|
|
|
inherit autotools pkgconfig github-releases
|
|
|
|
PACKAGECONFIG ??= "cdda-player"
|
|
PACKAGECONFIG[cdda-player] = "--with-cdda-player,--without-cdda-player,ncurses"
|
|
PACKAGECONFIG[cddb] = "--enable-cddb,--disable-cddb,libcddb"
|
|
PACKAGECONFIG[vcd-info] = "--enable-vcd-info,--disable-vcd-info,vcdimager"
|
|
|
|
# add -D_LARGEFILE64_SOURCE for 32bit targets
|
|
CFLAGS += "${@['-D_LARGEFILE64_SOURCE',''][d.getVar('SITEINFO_BITS') != '32']}"
|
|
|
|
PACKAGES += "${PN}-utils"
|
|
|
|
FILES:${PN} = "${libdir}/${BPN}${SOLIB}"
|
|
FILES:${PN}-utils = "${bindir}/*"
|
|
|
|
python libcdio_split_packages() {
|
|
libdir = d.expand('${libdir}')
|
|
do_split_packages(d, libdir, r'^lib(.*)\.so\..*', 'lib%s', 'libcdio %s library', extra_depends='', allow_links=True)
|
|
}
|
|
|
|
PACKAGESPLITFUNCS =+ "libcdio_split_packages"
|