mirror of
git://git.yoctoproject.org/meta-raspberrypi
synced 2026-07-16 04:56:10 +00:00
8058100868
For upstream yocto mirrors the git protocol was disabled lately. Appended 'protocol=https' in corresponding SRC_URIs to fixes following error: ERROR: ExpansionError during parsing [...]/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi-dev.bb bb.data_smart.ExpansionError: [...] \ ls-remote git://git.yoctoproject.org/yocto-kernel-cache failed with exit code 128, output: fatal: unable to connect to git.yoctoproject.org: git.yoctoproject.org[0: 104.18.0.115]: errno=Connection timed out git.yoctoproject.org[1: 104.18.1.115]: errno=Connection timed out git.yoctoproject.org[2: 2606:4700::6812:73]: errno=Network is unreachable git.yoctoproject.org[3: 2606:4700::6812:173]: errno=Network is unreachable The variable dependency chain for the failure is: fetcher_hashes_dummyfunc[vardepvalue] ERROR: Parsing halted due to errors, see error messages above Signed-off-by: Michael Weiß <michael.weiss@aisec.fraunhofer.de>
36 lines
1.5 KiB
BlitzBasic
36 lines
1.5 KiB
BlitzBasic
python __anonymous() {
|
|
if "linux-raspberrypi-dev" not in d.getVar("PREFERRED_PROVIDER_virtual/kernel"):
|
|
msg = "Skipping linux-raspberrypi-dev as it is not the preferred " + \
|
|
"provider of virtual/kernel."
|
|
raise bb.parse.SkipRecipe(msg)
|
|
}
|
|
|
|
LINUX_VERSION ?= "5.10.y"
|
|
LINUX_RPI_BRANCH ?= "rpi-5.10.y"
|
|
LINUX_RPI_KMETA_BRANCH ?= "yocto-5.10"
|
|
|
|
# Set default SRCREVs. Both the machine and meta SRCREVs are statically set
|
|
# to the as in 5.10 recipe, and hence prevent network access during parsing. If
|
|
# linux-yocto-dev is the preferred provider, they will be overridden to
|
|
# AUTOREV in following anonymous python routine and resolved when the
|
|
# variables are finalized.
|
|
SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-raspberrypi-dev", "${AUTOREV}", "89399e6e7e33d6260a954603ca03857df594ffd3", d)}'
|
|
SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-raspberrypi-dev", "${AUTOREV}", "a19886b00ea7d874fdd60d8e3435894bb16e6434", d)}'
|
|
|
|
KMETA = "kernel-meta"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/raspberrypi/linux.git;name=machine;branch=${LINUX_RPI_BRANCH};protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=${LINUX_RPI_KMETA_BRANCH};destsuffix=${KMETA};protocol=https \
|
|
file://powersave.cfg \
|
|
file://android-drivers.cfg \
|
|
"
|
|
|
|
require linux-raspberrypi.inc
|
|
|
|
KERNEL_DTC_FLAGS += "-@ -H epapr"
|
|
|
|
# Disable version check so that we don't have to edit this recipe every time
|
|
# upstream bumps the version
|
|
KERNEL_VERSION_SANITY_SKIP = "1"
|