mirror of
git://git.yoctoproject.org/meta-raspberrypi
synced 2026-04-02 02:49:12 +00:00
e67feeff48
* it's failing to build since the upgrade in:
https://git.openembedded.org/meta-openembedded/commit/?id=711c6fbce39df685225bca081c5f42bae2de658b
* fixes
../git/core/libcamera_app.cpp: In member function 'void LibcameraApp::ConfigureViewfinder()':
../git/core/libcamera_app.cpp:327:25: error: 'class libcamera::CameraConfiguration' has no member named 'transform'
327 | configuration_->transform = options_->transform;
| ^~~~~~~~~
* be aware that the repository and libraries were removed in 1.4.0 version with:
0ca9f41fea
but I'll leave that change to someone actually using this, I was just fixing
the build issue found in world builds
* tweak FILES to package library symlink without "lib" prefix to fix:
ERROR: libcamera-apps-1.4.2+git-r0 do_package: QA Issue: libcamera-apps: Files/directories were installed but not shipped in any package:
/usr/lib/rpicam_app.so
Please set FILES such that these items are packaged. Alternatively if they are unneeded, avoid installing them or delete them within do_install.
libcamera-apps: 1 installed and not shipped files. [installed-vs-shipped]
Signed-off-by: Martin Jansa <martin.jansa@gmail.com>
45 lines
1.7 KiB
BlitzBasic
45 lines
1.7 KiB
BlitzBasic
SUMMARY = "A suite of libcamera-based apps"
|
|
DESCRIPTION = "This is a small suite of libcamera-based apps that aim to \
|
|
copy the functionality of the existing \"raspicam\" apps."
|
|
HOMEPAGE = "https://github.com/raspberrypi/libcamera-apps"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://license.txt;md5=a0013d1b383d72ba4bdc5b750e7d1d77"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/raspberrypi/libcamera-apps.git;protocol=https;branch=main \
|
|
file://0001-utils-version.py-use-usr-bin-env-in-shebang.patch \
|
|
file://0002-Revert-Support-compressed-pixel-formats-when-saving-.patch \
|
|
"
|
|
PV = "1.4.2+git${SRCPV}"
|
|
SRCREV = "9ae39f85ae6bee9761c36b9b5b80d675bc1fa369"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "libcamera libexif jpeg tiff libpng boost"
|
|
|
|
PACKAGECONFIG ??= "drm"
|
|
PACKAGECONFIG[libav] = "-Denable_libav=true, -Denable_libav=false, libav"
|
|
PACKAGECONFIG[drm] = "-Denable_drm=true, -Denable_drm=false, libdrm"
|
|
PACKAGECONFIG[egl] = "-Denable_egl=true, -Denable_egl=false, virtual/egl"
|
|
PACKAGECONFIG[qt] = "-Denable_qt=true, -Denable_qt=false, qtbase"
|
|
PACKAGECONFIG[opencv] = "-Denable_opencv=true, -Denable_opencv=false, opencv"
|
|
PACKAGECONFIG[tflite] = "-Denable_tflite=true, -Denable_tflite=false, tensorflow-lite"
|
|
|
|
inherit meson pkgconfig
|
|
|
|
NEON_FLAGS = ""
|
|
NEON_FLAGS:aarch64 = "-Dneon_flags=arm64"
|
|
NEON_FLAGS:arm:raspberrypi3 = "-Dneon_flags=armv8-neon"
|
|
NEON_FLAGS:arm:raspberrypi4 = "-Dneon_flags=armv8-neon"
|
|
EXTRA_OEMESON += "${NEON_FLAGS}"
|
|
|
|
# QA Issue: /usr/bin/camera-bug-report contained in package libcamera-apps requires /usr/bin/python3
|
|
do_install:append() {
|
|
rm -v ${D}/${bindir}/camera-bug-report
|
|
}
|
|
|
|
# not picked automatically, because it's missing common 'lib' prefix
|
|
FILES:${PN}-dev += "${libdir}/rpicam_app.so"
|