mirror of
git://git.yoctoproject.org/poky
synced 2026-09-29 08:13:32 +00:00
37784b9822
In busybox the default location of symbolic link for command ip is /sbin/ip. But in iproute2, the alternatvie link for ip is /bin/ip. It will cause an error when running update-alternatives: Cannot register alternative ip to /bin/ip since it is already registered to /sbin/ip. [YOCTO #4855] (From OE-Core rev: b45f322abfa72fb0330aac9a1e4c86aebcc4598e) Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.3 KiB
PHP
38 lines
1.3 KiB
PHP
SUMMARY = "TCP / IP networking and traffic control utilities"
|
|
DESCRIPTION = "Iproute2 is a collection of utilities for controlling \
|
|
TCP / IP networking and traffic control in Linux. Of the utilities ip \
|
|
and tc are the most important. ip controls IPv4 and IPv6 \
|
|
configuration and tc stands for traffic control."
|
|
HOMEPAGE = "http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a \
|
|
file://ip/ip.c;beginline=3;endline=8;md5=689d691d0410a4b64d3899f8d6e31817"
|
|
|
|
DEPENDS = "flex-native bison-native iptables"
|
|
|
|
inherit update-alternatives
|
|
|
|
EXTRA_OEMAKE = "CC='${CC}' KERNEL_INCLUDE=${STAGING_INCDIR} DOCDIR=${docdir}/iproute2 SUBDIRS='lib tc ip' SBINDIR='${base_sbindir}' LIBDIR='${libdir}'"
|
|
|
|
do_install () {
|
|
oe_runmake DESTDIR=${D} install
|
|
mv ${D}${base_sbindir}/ip ${D}${base_sbindir}/ip.iproute2
|
|
install -d ${D}${datadir}
|
|
mv ${D}/share/* ${D}${datadir}/ || true
|
|
rm ${D}/share -rf || true
|
|
}
|
|
|
|
# There are only .so files in iproute2
|
|
INSANE_SKIP_${PN} = "dev-so"
|
|
|
|
FILES_${PN} += "${libdir}/tc"
|
|
FILES_${PN}-dbg += "${libdir}/tc/.debug"
|
|
|
|
ALTERNATIVE_${PN} = "ip"
|
|
ALTERNATIVE_TARGET[ip] = "${base_sbindir}/ip.${BPN}"
|
|
ALTERNATIVE_LINK_NAME[ip] = "${base_sbindir}/ip"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
PARALLEL_MAKE = ""
|