mirror of
git://git.yoctoproject.org/poky
synced 2026-08-16 18:50:59 +00:00
7256436957
import patches from ubuntu to fix CVE-2023-2602 CVE-2023-2603 Upstream-Status: Backport [import from ubuntu https://git.launchpad.net/ubuntu/+source/libcap2/tree/debian/patches?h=ubuntu/focal-security Upstream commit https://git.kernel.org/pub/scm/libs/libcap/libcap.git/commit/?id=bc6b36682f188020ee4770fae1d41bde5b2c97bb & https://git.kernel.org/pub/scm/libs/libcap/libcap.git/commit/?id=422bec25ae4a1ab03fd4d6f728695ed279173b18] (From OE-Core rev: d0718a43a00223aa074f14e769214ba11d4f8ef2) Signed-off-by: Vijay Anusuri <vanusuri@mvista.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
82 lines
2.5 KiB
BlitzBasic
82 lines
2.5 KiB
BlitzBasic
SUMMARY = "Library for getting/setting POSIX.1e capabilities"
|
|
DESCRIPTION = "A library providing the API to access POSIX capabilities. \
|
|
These allow giving various kinds of specific privileges to individual \
|
|
users, without giving them full root permissions."
|
|
HOMEPAGE = "http://sites.google.com/site/fullycapable/"
|
|
# no specific GPL version required
|
|
LICENSE = "BSD-3-Clause | GPLv2"
|
|
LIC_FILES_CHKSUM = "file://License;md5=3f84fd6f29d453a56514cb7e4ead25f1"
|
|
|
|
DEPENDS = "hostperl-runtime-native gperf-native"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/libs/security/linux-privs/${BPN}2/${BPN}-${PV}.tar.xz \
|
|
file://0001-ensure-the-XATTR_NAME_CAPS-is-defined-when-it-is-use.patch \
|
|
file://0002-tests-do-not-run-target-executables.patch \
|
|
file://0001-tests-do-not-statically-link-a-test.patch \
|
|
file://CVE-2023-2602.patch \
|
|
file://CVE-2023-2603.patch \
|
|
"
|
|
SRC_URI[md5sum] = "7416119c9fdcfd0e8dd190a432c668e9"
|
|
SRC_URI[sha256sum] = "1005e3d227f2340ad1e3360ef8b69d15e3c72a29c09f4894d7aac038bd26e2be"
|
|
|
|
UPSTREAM_CHECK_URI = "https://www.kernel.org/pub/linux/libs/security/linux-privs/${BPN}2/"
|
|
|
|
inherit lib_package
|
|
|
|
# do NOT pass target cflags to host compilations
|
|
#
|
|
do_configure() {
|
|
# libcap uses := for compilers, fortunately, it gives us a hint
|
|
# on what should be replaced with ?=
|
|
sed -e 's,:=,?=,g' -i Make.Rules
|
|
sed -e 's,^BUILD_CFLAGS ?= $(.*CFLAGS),BUILD_CFLAGS := $(BUILD_CFLAGS),' -i Make.Rules
|
|
}
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
|
|
PACKAGECONFIG_class-native ??= ""
|
|
|
|
PACKAGECONFIG[pam] = "PAM_CAP=yes,PAM_CAP=no,libpam"
|
|
|
|
EXTRA_OEMAKE = " \
|
|
INDENT= \
|
|
lib='${baselib}' \
|
|
RAISE_SETFCAP=no \
|
|
DYNAMIC=yes \
|
|
BUILD_GPERF=yes \
|
|
"
|
|
|
|
EXTRA_OEMAKE_append_class-target = " SYSTEM_HEADERS=${STAGING_INCDIR}"
|
|
|
|
# these are present in the libcap defaults, so include in our CFLAGS too
|
|
CFLAGS += "-D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
|
|
|
|
do_compile() {
|
|
oe_runmake ${PACKAGECONFIG_CONFARGS}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install \
|
|
${PACKAGECONFIG_CONFARGS} \
|
|
DESTDIR="${D}" \
|
|
prefix="${prefix}" \
|
|
SBINDIR="${sbindir}"
|
|
}
|
|
|
|
do_install_append() {
|
|
# Move the library to base_libdir
|
|
install -d ${D}${base_libdir}
|
|
if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
|
|
mv ${D}${libdir}/libcap* ${D}${base_libdir}
|
|
if [ -d ${D}${libdir}/security ]; then
|
|
mv ${D}${libdir}/security ${D}${base_libdir}
|
|
fi
|
|
fi
|
|
}
|
|
|
|
FILES_${PN}-dev += "${base_libdir}/*.so"
|
|
|
|
# pam files
|
|
FILES_${PN} += "${base_libdir}/security/*.so"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|