mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 17:47:36 +00:00
b1bdeda784
Some fix upstream addresses the issue, it isn't clear which change this was. Our current version doesn't have issues with the test image though so we can exclude. (From OE-Core rev: 65124cac1ac1d0b746eacfe128da19c353f07eb0) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.2 KiB
BlitzBasic
58 lines
2.2 KiB
BlitzBasic
SUMMARY = "Provides support for the Tag Image File Format (TIFF)"
|
|
DESCRIPTION = "Library provides support for the Tag Image File Format \
|
|
(TIFF), a widely used format for storing image data. This library \
|
|
provide means to easily access and create TIFF image files."
|
|
HOMEPAGE = "http://www.libtiff.org/"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=34da3db46fab7501992f9615d7e158cf"
|
|
|
|
CVE_PRODUCT = "libtiff"
|
|
|
|
SRC_URI = "http://download.osgeo.org/libtiff/tiff-${PV}.tar.gz \
|
|
"
|
|
SRC_URI[sha256sum] = "eb0484e568ead8fa23b513e9b0041df7e327f4ee2d22db5a533929dfc19633cb"
|
|
|
|
# exclude betas
|
|
UPSTREAM_CHECK_REGEX = "tiff-(?P<pver>\d+(\.\d+)+).tar"
|
|
|
|
# Tested with check from https://security-tracker.debian.org/tracker/CVE-2015-7313
|
|
# and 4.3.0 doesn't have the issue
|
|
CVE_CHECK_WHITELIST += "CVE-2015-7313"
|
|
|
|
inherit autotools multilib_header
|
|
|
|
CACHED_CONFIGUREVARS = "ax_cv_check_gl_libgl=no"
|
|
|
|
PACKAGECONFIG ?= "cxx jpeg zlib lzma \
|
|
strip-chopping extrasample-as-alpha check-ycbcr-subsampling"
|
|
|
|
PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx,,"
|
|
PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg,"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib,"
|
|
PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz,"
|
|
|
|
# Convert single-strip uncompressed images to multiple strips of specified
|
|
# size (default: 8192) to reduce memory usage
|
|
PACKAGECONFIG[strip-chopping] = "--enable-strip-chopping,--disable-strip-chopping,,"
|
|
|
|
# Treat a fourth sample with no EXTRASAMPLE_ value as being ASSOCALPHA
|
|
PACKAGECONFIG[extrasample-as-alpha] = "--enable-extrasample-as-alpha,--disable-extrasample-as-alpha,,"
|
|
|
|
# Control picking up YCbCr subsample info. Disable to support files lacking
|
|
# the tag
|
|
PACKAGECONFIG[check-ycbcr-subsampling] = "--enable-check-ycbcr-subsampling,--disable-check-ycbcr-subsampling,,"
|
|
|
|
# Support a mechanism allowing reading large strips (usually one strip files)
|
|
# in chunks when using TIFFReadScanline. Experimental 4.0+ feature
|
|
PACKAGECONFIG[chunky-strip-read] = "--enable-chunky-strip-read,--disable-chunky-strip-read,,"
|
|
|
|
PACKAGES =+ "tiffxx tiff-utils"
|
|
FILES_tiffxx = "${libdir}/libtiffxx.so.*"
|
|
FILES_tiff-utils = "${bindir}/*"
|
|
|
|
do_install_append() {
|
|
oe_multilib_header tiffconf.h
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|