mirror of
git://git.yoctoproject.org/poky
synced 2026-10-01 21:46:01 +00:00
cd725a0b96
This is a stable bugfix release, with the following changes: Windows Only check to see if the ICC profile changes when the display changes or we gain focus Fixed window resize handing when using the D3D12 renderer Fixed Xbox controller detection on Windows XP macOS Fixed long delay in SDL_CloseAudioDevice() Linux Fixed crash in Wayland_HasScreenKeyboardSupport() FreeBSD Fixed building without GNU sort, but warn that dynamic libraries won't be found Emscripten Fixed infinite recursion related to mutexes on startup OS/2 Fixes and improvements to SDL_LoadObject() functionality (From OE-Core rev: 8dd54a5b441fa87fdbe076b89a496aa6e6c230fe) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> (cherry picked from commit 0091bbe02399f49b7da1ebf9b45541b26fb2ce12) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
86 lines
3.8 KiB
BlitzBasic
86 lines
3.8 KiB
BlitzBasic
SUMMARY = "Simple DirectMedia Layer"
|
|
DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
|
|
library designed to provide low level access to audio, keyboard, mouse, \
|
|
joystick, 3D hardware via OpenGL, and 2D video framebuffer."
|
|
HOMEPAGE = "http://www.libsdl.org"
|
|
BUGTRACKER = "http://bugzilla.libsdl.org/"
|
|
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Zlib & BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "\
|
|
file://LICENSE.txt;md5=68a088513da90254b2fbe664f42af315 \
|
|
file://src/hidapi/LICENSE.txt;md5=7c3949a631240cb6c31c50f3eb696077 \
|
|
file://src/hidapi/LICENSE-bsd.txt;md5=b5fa085ce0926bb50d0621620a82361f \
|
|
file://src/video/yuv2rgb/LICENSE;md5=79f8f3418d91531e05f0fc94ca67e071 \
|
|
"
|
|
|
|
# arm-neon adds MIT license
|
|
LICENSE:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', '& MIT', '', d)}"
|
|
LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', 'file://src/video/arm/pixman-arm-neon-asm.h;md5=9a9cc1e51abbf1da58f4d9528ec9d49b;beginline=1;endline=24', '', d)}"
|
|
|
|
PROVIDES = "virtual/libsdl2"
|
|
|
|
SRC_URI = "http://www.libsdl.org/release/SDL2-${PV}.tar.gz \
|
|
"
|
|
SRC_URI:append:class-native = " file://0001-Disable-libunwind-in-native-OE-builds-by-not-looking.patch"
|
|
|
|
S = "${WORKDIR}/SDL2-${PV}"
|
|
|
|
SRC_URI[sha256sum] = "b35ef0a802b09d90ed3add0dcac0e95820804202914f5bb7b0feb710f1a1329f"
|
|
|
|
inherit cmake lib_package binconfig-disabled pkgconfig upstream-version-is-even
|
|
|
|
BINCONFIG = "${bindir}/sdl2-config"
|
|
|
|
CVE_PRODUCT = "simple_directmedia_layer sdl"
|
|
|
|
EXTRA_OECMAKE = "-DSDL_OSS=OFF -DSDL_ESD=OFF -DSDL_ARTS=OFF \
|
|
-DSDL_DISKAUDIO=OFF -DSDL_NAS=OFF -DSDL_ESD_SHARED=OFF \
|
|
-DSDL_DUMMYVIDEO=OFF \
|
|
-DSDL_RPI=OFF \
|
|
-DSDL_PTHREADS=ON \
|
|
-DSDL_RPATH=OFF \
|
|
-DSDL_SNDIO=OFF \
|
|
-DSDL_X11_XCURSOR=OFF \
|
|
-DSDL_X11_XDBE=OFF \
|
|
-DSDL_X11_XFIXES=OFF \
|
|
-DSDL_X11_XINPUT=OFF \
|
|
-DSDL_X11_XRANDR=OFF \
|
|
-DSDL_X11_XSCRNSAVER=OFF \
|
|
-DSDL_X11_XSHAPE=OFF \
|
|
"
|
|
|
|
# opengl packageconfig factored out to make it easy for distros
|
|
# and BSP layers to pick either (desktop) opengl, gles2, or no GL
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
|
|
|
|
PACKAGECONFIG:class-native = "x11 ${PACKAGECONFIG_GL}"
|
|
PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${PACKAGECONFIG_GL}"
|
|
PACKAGECONFIG ??= " \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11 vulkan', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \
|
|
${@bb.utils.contains("TUNE_FEATURES", "neon","arm-neon","",d)} \
|
|
"
|
|
PACKAGECONFIG[alsa] = "-DSDL_ALSA=ON,-DSDL_ALSA=OFF,alsa-lib,"
|
|
PACKAGECONFIG[arm-neon] = "-DSDL_ARMNEON=ON,-DSDL_ARMNEON=OFF"
|
|
PACKAGECONFIG[directfb] = "-DSDL_DIRECTFB=ON,-DSDL_DIRECTFB=OFF,directfb,directfb"
|
|
PACKAGECONFIG[gles2] = "-DSDL_OPENGLES=ON,-DSDL_OPENGLES=OFF,virtual/libgles2"
|
|
PACKAGECONFIG[jack] = "-DSDL_JACK=ON,-DSDL_JACK=OFF,jack"
|
|
PACKAGECONFIG[kmsdrm] = "-DSDL_KMSDRM=ON,-DSDL_KMSDRM=OFF,libdrm virtual/libgbm"
|
|
# The hidraw support doesn't catch Xbox, PS4 and Nintendo controllers,
|
|
# so we'll just use libusb when it's available.
|
|
PACKAGECONFIG[libusb] = ",,libusb1"
|
|
PACKAGECONFIG[opengl] = "-DSDL_OPENGL=ON,-DSDL_OPENGL=OFF,virtual/egl"
|
|
PACKAGECONFIG[pulseaudio] = "-DSDL_PULSEAUDIO=ON,-DSDL_PULSEAUDIO=OFF,pulseaudio"
|
|
PACKAGECONFIG[vulkan] = "-DSDL_VULKAN=ON,-DSDL_VULKAN=OFF"
|
|
PACKAGECONFIG[wayland] = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
|
|
PACKAGECONFIG[x11] = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
|
|
|
|
CFLAGS:append:class-native = " -DNO_SHARED_MEMORY"
|
|
|
|
FILES:${PN} += "${datadir}/licenses/SDL2/LICENSE.txt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|