mirror of
git://git.yoctoproject.org/poky
synced 2026-09-28 22:28:01 +00:00
6e73a100ba
Summary for 1.10.4 libpcap release
Source code:
Fix spaces before tabs in indentation.
rpcap:
Fix name of launchd service.
Documentation:
Document use of rpcapd with systemd, launchd, inetd, and xinetd.
Building and testing:
Require at least pkg-config 0.17.0, as we use --static.
Get rid of the remains of gnuc.h.
Require at least autoconf 2.69.
Update config.{guess,sub}, timestamps 2023-01-01,2023-01-21.
(From OE-Core rev: cc7a3c6cb32b4a8d2677159cd106068b5f2d75e8)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
(cherry picked from commit da76bde131a7fe0833c9fd59a1ca48edaed6fa54)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
44 lines
1.8 KiB
BlitzBasic
44 lines
1.8 KiB
BlitzBasic
SUMMARY = "Interface for user-level network packet capture"
|
|
DESCRIPTION = "Libpcap provides a portable framework for low-level network \
|
|
monitoring. Libpcap can provide network statistics collection, \
|
|
security monitoring and network debugging."
|
|
HOMEPAGE = "http://www.tcpdump.org/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=53067&atid=469577"
|
|
SECTION = "libs/network"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5eb289217c160e2920d2e35bddc36453 \
|
|
file://pcap.h;beginline=1;endline=32;md5=39af3510e011f34b8872f120b1dc31d2"
|
|
DEPENDS = "flex-native bison-native"
|
|
|
|
SRC_URI = "https://www.tcpdump.org/release/${BP}.tar.gz"
|
|
SRC_URI[sha256sum] = "ed19a0383fad72e3ad435fd239d7cd80d64916b87269550159d20e47160ebe5f"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig
|
|
|
|
BINCONFIG = "${bindir}/pcap-config"
|
|
|
|
# Explicitly disable dag support. We don't have recipe for it and if enabled here,
|
|
# configure script poisons the include dirs with /usr/local/include even when the
|
|
# support hasn't been detected. Do the same thing for DPDK.
|
|
EXTRA_OECONF = " \
|
|
--with-pcap=linux \
|
|
--without-dag \
|
|
--without-dpdk \
|
|
"
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
|
"
|
|
PACKAGECONFIG[bluez5] = "--enable-bluetooth,--disable-bluetooth,bluez5"
|
|
PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
PACKAGECONFIG[libnl] = "--with-libnl,--without-libnl,libnl"
|
|
|
|
do_configure:prepend () {
|
|
#remove hardcoded references to /usr/include
|
|
sed 's|\([ "^'\''I]\+\)/usr/include/|\1${STAGING_INCDIR}/|g' -i ${S}/configure.ac
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|